finding location of an element in a matrix

We're glad you came by, but you might find what you're looking for elsewhere. TI-Basic Developer is not the site it once was. While its information on commands and other calculator features remains almost second-to-none, its forum, archives, and even hosting service, Wikidot, have been decaying for years. The calculator community would love to see what you're working on, or help you in your next coding adventure, but TI-Basic Developer is no longer the place to do it. Instead, you should head over to Cemetech (primarily American) or TI-Planet (primarily international). Both are active, well-established forums with their own archives, chatrooms, reference material, and abundant coding tools and resources. We'll see you there, we hope.

Forum Attachments

Summary:

how do you find the location of an element in a matrix

finding location of an element in a matrix

homercimpson 09 Aug 2010 03:04

Say i have a column matrix [a,b,c…z] and i store it in the variable AA. how would i go about finding the location of an element like b?
The question is the reverse of AA[2]=b. I'm asking how to do something like AA[b]=2. Another example would be AA[c]=3. And keep in mind a,b,c…z aren't the actual elements i'm using. my matrix begins something like [h,he,li,br…Rn]

Re: finding location of an element in a matrix

Weregoose 09 Aug 2010 06:00

Disclaimer: This is for the language associated with the TI-83+ through TI-84+SE models. I'm unfamiliar with the syntax you're using.

Let's say I have a matrix with five rows and three columns…

[A]
       [[4 6 5]
        [3 9 5]
        [4 1 2]
        [7 5 3]
        [8 1 6]]

…and I use Matr►list( to transform the second column into a list:

Matr►list([A],2,
L₁
            Done
L₁
     {6 9 1 5 1}

(Lists are more flexible, and should be the default if you're working with arrangements of numbers that don't require multiple rows.)

Suppose I want to find out which element position has a five in it. Performing the test outright…

L₁=5
     {0 0 0 1 0}

…returns a list where each element has been compared. The fourth slot returned "true," so it evidently holds the five.

If you were to now multiply this result by a new list where each element identifies with the position that it occupies…

Ans*{1,2,3,4,5
     {0 0 0 4 0}

…just the four gets multiplied by the "1" you saw earlier. You can now take the max( of this result to obtain your answer.

A seq( command will produce the ordered list shown above, but there is a different approach: assuming that you have a list prepared in Ans, you can multiply Ans by zero, not( all of the elements inside it to turn it into a list of ones, and then take the cumSum( of that to get the numbers in increasing order. For example:

L₁
     {6 9 1 5 1}
cumSum(not(0Ans
     {1 2 3 4 5}

Proceed to multiply that by the binary list generated from a comparison, and then pull out the position number using max(.

max((L₁=5)cumSum
(not(0L₁
               4

Addendum: You can use a For( loop to test each column of a multicolumnar matrix.

---

Layperson's technique (for the simple-minded):

0→A
0→B
dim([A]→L1
For(R,1,L1(1
For(C,1,L1(2
If 5=[A](R,C
Then
R→A
C→B
End
End
End
Disp "ROW:",A,"COLUMN:",B

Last edited on 09 Aug 2010 22:05 by Weregoose Show more