Random pair genrator for 2 digit numbers where...

We're glad you came by, but you might find what you're looking for elsewhere. TI-Basic Developer is not the site it once was. While its information on commands and other calculator features remains almost second-to-none, its forum, archives, and even hosting service, Wikidot, have been decaying for years. The calculator community would love to see what you're working on, or help you in your next coding adventure, but TI-Basic Developer is no longer the place to do it. Instead, you should head over to Cemetech (primarily American) or TI-Planet (primarily international). Both are active, well-established forums with their own archives, chatrooms, reference material, and abundant coding tools and resources. We'll see you there, we hope.

Forum Attachments

Summary:

both numbers have the same first digit and the second digits add up to 10.

Random pair generator for 2 digit numbers where...

Benarius 09 Dec 2018 14:28

As my first contribution to this forum, I'd like to share my first problems I solved. I wonder if there are other solutions, so please comment. As part of a bigger program (Maths Trainer, doing fast arithmetic in your head, timed with highscore,etc) I need two random numbers as described in summary. You know those Mathemagic tricks…for numbers like 23×27, 68x62 or 42×48, you simply do the following. e.g. 46×44. Multiply 40×(40+10) add (6×4). Voila, you get 2024 within seconds in your head. The programm generates first one random number. Divide it by 10. I assign a variable to each for iPart() and fPart(). The iPart() is multiplied by 10 and added to fPart() which was first subtracted from 1 and muliplied by 10. Her is an example.

1. random number generated is 73 (so I need another which is 77)
2. divide 73 by 10 and assign to variable. A=7.3
3. B=ipart(A) giving me 7
4. C=fpart(A) giving me 0.3
5. B×10=70 and (1-C)×10=7 aded to gether giving me 77 assigned to D
6. result is 73 generated from 77

The rest is straight forward. Prompt and check that 77×73 is 5621. I want to add difficulty levels that shortens answer times. Also add highscores, nice UI,etc.

Here is the result so far:

:ClrHome
:Lbl A
:randInt(11,99)->A
:A/10->B
:A/10->C
:fpart(B)->D
:ipart(C)->E
:E×10->F
:(1-D)×10->G
:F+G->H
:A×H->I (fixed mistake pointed out by UEBERhelp)
:Disp A,H
:Prompt J
:If J=I
:Then
:ClrHome
:Output(5,8,"Bravo")
:Goto A
:Else
:ClrHome
:Output(5,8,"Boooo…")
:Goto A

Enjoy!

I am aware I can get rid of some variables and calculate some inside the commands. Also its just spaghetti code. But for the time it works.

In case you know of some more elegant solution to find the second nunber with the given requierments, let me know. I will post final results on my new wiki page.

Have a nice day.

Benarius

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 09 Dec 2018 16:29 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

UBERhelp1 09 Dec 2018 15:28

I actually found this pretty fun to play, but there are some ways to get a much more compact code. Here are just some optimizations for the code and some tweaks, for example when you play a new round it clears the "Bravo" or "Boooo…"

For some reason, the correct answer doesn't work? From your code, it only works if J=I, which means the correct answer for all of these is undefined because there is no value stored in I. Anyway, here is the code with that fixed by having the correct response be A*H. If that is not what you meant, then by all means just ignore that part of the code.

Also, I changed Prompt to Input because it allows you to put text there to say what to input.

Finally, in TI Basic you can leave off end quotes and parenthesis; for example:
:Output(5,8,"Bravo")
becomes
:Output(5,8,"Bravo
This just saves a few bytes. In small programs like this it doesn't really matter, but once programs begin to get larger every byte saved is important.

:Lbl A
:ClrHome
:randInt(11,99→A
:A/10→B
:fPart(B→D
:iPart(B→E
:E*10→F
:(1-D)*10→G
:F+G→H
:Disp A,H
:Input "Answer: ",J
:ClrHome
:If J=(AH)
:Then
:Output(5,8,"Bravo
:Pause
:Goto A
:Else
:Output(5,8,"Booo...
:Pause
:Goto A

As far as different answer times, I'm not sure if that's possible using TI Basic. The Input and Prompt act like pauses, in which no other code is running at the same time until an input is received.

Overall though, it seems surprisingly fun to play. I can't wait to see the finished product!

UBER

---

🧟Initiating Project Horde 🧟

Last edited on 09 Dec 2018 15:33 by UBERhelp1 Show more

Re: Random pair generator for 2 digit numbers where...

Benarius 09 Dec 2018 16:02

Hi UEBERhelp,

thanks for your reply. I missed a line where A×H->I just before the prompt. Your fix was If J=(A×H). I will fix it later. Thanks for the tips regards leaving out closing parts. Of course the final version will have some fancy UI and graphics. I am new to the 84 Plus CE but have found some commands where you can use seconds or I just assign a counting loop that measures delay in answering or a countdown that can be manually adjusted. Anyway, lots of work ahead. I want to implement a learning section which explains the tricks first and then a training section for each. And also you can select to be tested on all the tricks. The maths and code is not too much an issue for me. That's why the next step is learning how the display works. Putting info where I want it and also use menu functions. There is this program called MASTER which is a game to find 4 colored pegs. I use this to analyze how to create a nice UI. Will keep WIP posted. Thanks for your help. Benarius.

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

Trenly 09 Dec 2018 21:00

You may want to take a look at the memory leaks page. You have a pretty nasty one in your program. This means the longer the program runs, the slower it will get and it will eventually crash. If you need more information on memory leaks, I can try and explain after you read that page

Re: Random pair generator for 2 digit numbers where...

Benarius 09 Dec 2018 21:17

Thanks heaps Trenly. While making this program I displayed all varibales to see where the bugs are. During the test runs, I noticed how it got slower and slower while displaying faulty variable values in never ending loops. I was wondering why that is. I understand whats going on and how to prevent it in the future. It's time to draw flow charts again instead of spaghetti coding…lol.

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 09 Dec 2018 21:27 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

Trenly 09 Dec 2018 21:31

Fixing memory leaks is actually pretty easy on a small program like this. Another thing you may want to do is to have an exit condition, so that they can exit the loop without pressing [ON]. The final thing I would like to note, is that using input people can enter the operand * so they don't even have to enter the proper number. There is a way around this, but its a bit more advanced. If you would like to know about it, I can try explaining it.

However, I had a bit of time and optimized the short bit of code you had on this page. This is what I was able to come up with. I am leaving it uncommented so you can try and figure out what exactly I did and why. Again, if you have any questions feel free to ask.

Repeat not(J)
ClrHome
randInt(11,99→A
10iPart(.1A)+10(1-fPart(.1A→H
Disp A,H
Input "Answer:",J
ClrHome
If J:Then
Output(4,7,"Booo…
If J=(AH):Output(4,7,"Bravo
Pause 
End
End
ClrHome

Re: Random pair generator for 2 digit numbers where...

Benarius 09 Dec 2018 21:58

Wow…what an elegant solution. Just typed it in. So after each input you need to press enter to continue. Thanks for showing me how to compress everything to the shortest codes. At first I wasn't sure what Repeat() does, but now I see the beauty in it. I will build on the techniques shown by you. You halfed the ammount of lines. Thanks again. Benarius.

P.S Just one question. Can't the Then command be ommited?

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 09 Dec 2018 22:18 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

Trenly 09 Dec 2018 22:26

Well, if you indent it it shows it is necessary

Repeat not(J) //repeat until they enter 0 as an answer
    ClrHome
    randInt(11,99→A
    10iPart(.1A)+10(1-fPart(.1A→H
    Disp A,H
    Input "Answer:",J
    ClrHome
    If J:Then
        Output(4,7,"Booo…
        If J=(AH):Output(4,7,"Bravo
        Pause 
    End
End
ClrHome

The "Then" makes it so if they enter 0 it exits immediately and skips the pause statement. If you removed the "Then" you would also have to remove an "End"

Re: Random pair generator for 2 digit numbers where...

Benarius 09 Dec 2018 22:30

Got it. I didn't know that pressing 0 will exit. Cool stuff. Which editor can you recommend?

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

Trenly 09 Dec 2018 22:51

I use TokenIDE as my editor.

Edit:

Since you understood the first code I sent fairly easily, take a look at this code and tell me what you think:

Repeat not(J)
  "?→Str1
  ClrHome
  randInt(11,99→A
  10iPart(.1A)+10(1-fPart(.1A→H
  Disp A,H
  DelVar K
  DelVar J
  Output(3,1,"Answer:
  Repeat (K=105 and sub(Str1,1,1)≠"?") or K=45
    getKey→K
    If max(K={102,92,93,94,82,83,84,72,73,74
    Then
        K={102,92,93,94,82,83,84,72,73,74
        1+sum(not(cumSum(Ans=1
        Str1+sub("0123456789",Ans,1→Str1
        If sub(Str1,1,1)="?":sub(Str1,2,1→Str1
        Output(3,8,Str1
    End
    If K=23:Then
      Output(3,8,"       "
      If 1<length(Str1:Then
       sub(Str1,1,length(Str1)-1→Str1
      Else
       "?"→Str1
      End
      Output(3,8,Str1
    End
  End
  If K≠45:expr(Str1→J
  ClrHome
  If J:Then
    Output(4,7,"Booo…
    If J=AH:Output(4,7,"Bravo
    Pause 
  End
End
ClrHome

Last edited on 09 Dec 2018 23:05 by Trenly Show more

Re: Random pair generator for 2 digit numbers where...

Benarius 09 Dec 2018 23:46

Cool also. Limiting input to just number keys, Enter and del. But not sure about all the new goodies. Is there a " missing in "?→Str1 ? Also the Boo and Bravo is disappearing too fast. But fixed it. btw. had to delete all the indentations.

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 10 Dec 2018 00:03 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

Trenly 10 Dec 2018 00:53

No, there is no missing "

It seems to work fine on my calculator, the Boo and Bravo should stay until enter is pressed again

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 02:53

One more thing before this creative day is over. Do you know how to access lowercase letters within the calculator? I tried all options which I found online to no avail. It only works when I use the TiConnect CE or TokenIDE.

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 10 Dec 2018 02:53 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

Trenly 10 Dec 2018 02:56

you have to use one of the hexcodes. Keep in mind though that if you have a color calculator, you need to use the CE hexcodes instead

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 03:00

My ti84ce is brand new. V 5.3.1.0058. The Asm84CEPrgm is blocked…. :(

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

kg583 10 Dec 2018 03:12

You should be able to write the hexcode in TIConnect then send the program to your calculator. The program will still run via

Asm(prgmNAMEHERE

---

The solution to a complex problem is often a simple answer.

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 03:28

not working….I saw a lot of complaints on the web regards this issue…oh well….as long I can type lowcase within TI Connect, its ok. Thx anyway.

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 10 Dec 2018 03:28 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 03:32

But damn..this really bugs me now that after you shown me those HEX codes and all I COULD do with it…I CAN'T…..wtf…

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

Trenly 10 Dec 2018 03:41

How were you trying to access the token for Asm84CEPrgm?

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 03:45

It's blocked by a blue line over it. I have only Asm( and AsmComp( from catalog available.

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 10 Dec 2018 03:46 by Benarius Show more

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 03:57

I found a link where I can downgrade and install version5.3.0 with a downgrade tool. But not sure if I should or damage it or can upgrade again…ahhhh…so much pain——lol

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 04:26

I DID IT ANYWAY…Downgraded to 5.3.0.0037. Now Asm84CEPrgm is available again. Some new features will be missing, but that was a good trade off.

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 04:50

But still no success. I tried everything from calling the file with the token or vice versa, etc….can someone tell me step by step. Thanks heaps.

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 07:24

Finally got the solution from Kg583:

Create file e.g. LOWCASE with just that one entry below

:Asm84CEPrgmFDCB24DEC9

Then run Asm(prgLOWCASE)

DONE

I need to mention that I had to downgrade from Version 5.3.1 to 5.3.0

Thanks for all your help.

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

UBERhelp1 10 Dec 2018 11:58

Can't you just take the input as a string and check if that string equals the number? For example:

AH→Strg1
Input "Answer: ",Strg2
If Strg1=Strg2

Note, I don't have my calculator to test this out, but I think it would work.

---

🧟Initiating Project Horde 🧟

Re: Random pair generator for 2 digit numbers where...

Benarius 10 Dec 2018 12:12

Will try and let you know.

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair generator for 2 digit numbers where...

UBERhelp1 10 Dec 2018 14:35

Actually, I found a fix for that, and it takes up only a little space. It uses 2 strings and compares them to see if the answer is right. I actually typed it on my friend's calculator, so I won't be able to bugfix. It uses the toString( command, so if you don't have that you have to use a workaround - (I can't put the link to the page, but it is Number to String) Enjoy!

1→J
Repeat not(J)
ClrHome
randInt(11,99→A
10iPart(.1A)+10(1-fPart(.1A→H
Disp A,H
toString(AH
And→Strg1
Input "Answer:",Strg2
If Strg1=Strg2
Output(4,7,"Bravo
If Strg2="End"
0→J
If Strg2≠Strg1
Output(4,7,"Boooo...
End
ClrHome

It exits if you type in END as an answer.

---

🧟Initiating Project Horde 🧟

Last edited on 10 Dec 2018 15:29 by UBERhelp1 Show more

Re: Random pair generator for 2 digit numbers where...

(account deleted) 10 Dec 2018 16:57

Is that Axe?

EDIT: Nevermind, I see that you changed some abreviations for some commands, my bad.

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Last edited on 10 Dec 2018 16:59 by (account deleted) Show more

Re: Random pair generator for 2 digit numbers where...

Trenly 10 Dec 2018 17:12

UBERhelp1, while you could do that it is a bit less compatible. The toString command is not available on all calculators, which is why I had done the other way around and evaluated the string as a number. By limiting the input to numbers, it can also act as a method of error prevention. I am aware of both the number-to-string routines, but the less workarounds you have to use is generally considered better.

I see in your code you also used a section for if the strings are not equal; you don’t need this statement at all if you display the “Boo” before the “Bravo”. If you display the “Boo” first, then iff (yes, I mean iff, which is if and only if) the answer is correct will it display “Bravo”. This means you can make the program faster by assuming they are wrong and only changing the output if they are right.

A few other notes: You shouldn’t need the 1->J at the beginning since repeat loops always execute at least once. Instead of 0->J you can use DelVar J, which is smaller. The strings are not Strg1 and Strg2, they are Str1 and Str2.

Re: Random pair generator for 2 digit numbers where...

UBERhelp1 10 Dec 2018 17:43

I knew about the toString command, but if it is available then it helps. For the iff, that's a really good point. I didn't think of that. For the string abbreviation (strg) I was trying to type this up really fast and missed that. I literally wrote the program in 5 minutes and just made sure it functioned before posting it lol 😂

---

🧟Initiating Project Horde 🧟

Re: Random pair genrator for 2 digit numbers where...

Benarius 12 Dec 2018 12:04

I got the architecture ready to put in this code. Can you tell me how best to add a "Play again?" after each try? I tried with input() and getKey() but I seem to not understand the repeat() command, yet. Thanks in advance.

Meanwhile I get started with the next tricks. Multiply by 11 and square ending in 5s, etc.

Repeat not(J)
ClrHome
randInt(11,99→A
10iPart(.1A)+10(1-fPart(.1A→H
Disp A,H
Input "Answer:",J
ClrHome
If J:Then
Output(4,7,"Booo…
If J=(AH):Output(4,7,"Bravo
Pause 
End
End
ClrHome

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 12 Dec 2018 12:05 by Benarius Show more

Re: Random pair genrator for 2 digit numbers where...

Benarius 12 Dec 2018 12:26

Wrong alert

---

…indistinctness is my forte…
J.M.W. Turner

Last edited on 12 Dec 2018 12:48 by Benarius Show more

Re: Random pair genrator for 2 digit numbers where...

UBERhelp1 12 Dec 2018 12:36

You could just say

Disp "Play Again?
Input "Yes(1) No(0)",K
If K
Goto PA
Goto TP

The label PA is only reached if K=1, any other number will make it go to TP.

Also, your method of doing it has a memory leak. The If command is exited before it reaches the end. The more you play, the worse the leak.

The play again text was changed for compatibility among different calculators. IDK if you plan on making it compatible, but it is probably better to start now if you want it to be.

---

🧟Initiating Project Horde 🧟

Last edited on 12 Dec 2018 12:41 by UBERhelp1 Show more

Re: Random pair genrator for 2 digit numbers where...

Benarius 12 Dec 2018 12:49

Just realised there is a mistake. I will try yours. Thanks heaps.

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair genrator for 2 digit numbers where...

Benarius 12 Dec 2018 12:55

I had to make some more changes to make it work. Here it is.

Lbl PA

Repeat not(J)
ClrHome
randInt(11,99→A
10iPart(.1A)+10(1-fPart(.1A→H
Output(3,1,"Multiply")
Output(3,10,A)
Output(3,13,"x")
Output(3,15,H)
Input "Answer:",J
ClrHome
If J≠(AH):Then
Output(4,7,"Booo…
Goto RP
Else
If J=(AH):Output(4,7,"Bravo
Goto RP
Pause 

Lbl RP
Disp "Play Again?
Input "Yes(1) No(0)",K
If K
Goto PA
Goto TP

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair genrator for 2 digit numbers where...

UBERhelp1 12 Dec 2018 13:05

I think there is another memory leak. Actually, maybe 2.

You leave both an if statement and a loop with gotos.

Lbl PA

ClrHome
randInt(11,99→A
10iPart(.1A)+10(1-fPart(.1A→H
Output(3,1,"Multiply")
Output(3,10,A)
Output(3,13,"x")
Output(3,15,H)
Input "Answer:",J
ClrHome
If J≠(AH):Then
Output(4,7,"Booo…
Else
Output(4,7,"Bravo
End              //fixed leak of jumping out of the if, I think.

Pause 
Disp "Play Again?
Input "Yes(1) No(0)",K
If K
Goto PA
Goto TP

The loop appears to be unnecessary because of the replay feature that was added. Since the loop wasn't actually being used, I removed it. Also, if both of the branches of the if statement go to the label RP, then you can just remove that label and put what was in that label right below the if statement.

---

🧟Initiating Project Horde 🧟

Re: Random pair genrator for 2 digit numbers where...

Trenly 12 Dec 2018 15:08

Yep, those look like memory leaks to me. But Also, why use input for K to jump to labels, you could just do:

Menu(“Play Again?”,”Yes”,PA,”No”,TP

The best practice in programming is to avoid using
Goto as much as possible, since it has such high potential to cause memory leaks. UBERhelp1 posted one way to fix the leaks, but keeping the Repeat loop could also fix it:

Repeat not(J)
ClrHome
randInt(11,99→A
10iPart(.1A)+10(1-fPart(.1A→H
Output(3,1,"Multiply")
Output(3,10,A)
Output(3,13,"x")
Output(3,15,H)
Input "Answer:",J
ClrHome
If J≠(AH):Then
Output(4,7,"Booo…
Goto RP
Else
If J=(AH):Output(4,7,"Bravo
Pause 
Disp "Play Again?
Input "Yes(1) No(0)",J
End
Goto TP

The whole point of using Repeat or While loops is so that you don’t have to create your own loops using Lbl and Goto. Just remember, the cause of 100% of memory leaks is a Goto statement.

Last edited on 12 Dec 2018 16:10 by Trenly Show more

Re: Random pair genrator for 2 digit numbers where...

Benarius 12 Dec 2018 20:30

Thanks UEBERhelp. Trenly just fixed it all in the Projects code. You will also get a mention in the credits. I will load up thec omplete fixed version now again. 1.0.1

---

…indistinctness is my forte…
J.M.W. Turner

Re: Random pair genrator for 2 digit numbers where...

Benarius 13 Dec 2018 01:43

This thread is almost coming to an end as most action happens now on the HQ for the mental math trainer found here: http://tibasicdev.wikidot.com/forum/t-9315371/mental-arithmetic-trainer#post-4084449

I wanna thank everybody that got involved and has helped with this small but effective code. I can and will use it a 100 times within my program. All I have to change is the formula. And of course I have to squeeze in the trick explanation on one screen in the trick explanatiom section. But it all works like clockwork.

Thanks again to all. Hope to see you in the other thread.

Best regards

Benarius

---

…indistinctness is my forte…
J.M.W. Turner