Barebones Mastermind Game

Forum Attachments

Summary:

This, while a bit larger than our example, is very rich in features, and has actual RED and WHITE peg counts.

Barebones Mastermind Game

Josiah W 11 Feb 2014 18:42

This isn't your parents' Mastermind game!
This program is 439 bytes (with the name MSTRMIND) and includes such features as:

• A number input system without using Input (takes a bit from our Number Pad Routine)
• As graphical an interface as the homescreen can offer
• Red and white pegs (formula from Wolfram Mathworld
• Bug-free!

This is the formula for white pegs, as used in the program:
where c_i is the amount of times that i is in the code, g_i is how many times it is in the guess, and r is the amount of red pegs. Red pegs are how many numbers are right and in their correct position, white pegs are how many numbers are right, but in the wrong position.
Now for the boring stuff…

Rules

In this Mastermind clone, you have 15 tries to guess a code of 4 numbers randomly generated by the calculator.

Controls

Use the number pad to enter in numbers, LEFT to undo one letter, and ENTER to guess. It will then tell you the red and white peg count, and if there are 4 red pegs, you win! Press ENTER to get past the win screen. Press CLEAR to exit at any time during play.

I've spent 3 months with this program, and I've decided to release it now, as I think it's good enough to be another one of our examples.
Source code:

ClrHome
"?
Disp "NUMBER:","",Ans,Ans,Ans,Ans
Output(8,1,"RED: 0  WHITE: 0
DelVar TDelVar GDelVar Rint(10rand(4→L1
4→dim(L2
Repeat T=14 or K=45 or R=4
Repeat Ans
getKey
End
Ans(102≠Ans)-13int(Ans/13(2>abs(5-abs(5-abs(Ans-83→K
If Ans=105 and G=4
Then
For(X,1,4
Output(2+X,3+T,L2(X
End
DelVar GT+1→T
sum(L1=L2→R
Output(8,6,Ans
Output(8,16,‾Ans+sum(seq(min(sum(L1=X),sum(L2=X)),X,0,9
Output(1,9,"    //4 spaces
Else
If Ans≤9 and G≠4
Then
G+1→G
K→L2(Ans
End
If Ans=24 and G
Then
G-1→G
Output(1,Ans+9," //1 space
End
End
For(X,0,G
If X
Output(1,8+X,L2(X
End
End
For(X,1,4
Output(2+X,1,L1(X
End
If K≠45
Then
Output(1,1,"YOU "+sub("WIN!   LOSE...",8-7(R=4),7
Pause 
End
DelVar GDelVar KDelVar RDelVar TDelVar XDelVar L1DelVar L2ClrHome

Whaddaya think? Any improvements or suggestions? And can this be integrated with the Mastermind example here?

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Last edited on 11 Feb 2014 20:13 by Josiah W Show more

Re: Barebones Mastermind Game

Silver Phantom 12 Feb 2014 15:55

so it looks like your code is solid. i do have one question regarding gameplay, if the answer is a number with multiples of the same number, like 4557, how will the guess system look like if i place a 5 in the 2 slot

---

The Silver Phantom welcomes you

Re: Barebones Mastermind Game

Josiah W 14 Feb 2014 15:41

If you place a 5 in the second slot, and your num is like 4557 or something, then that would count as 1 red peg. If the 5 were in the first or last spot, though, that would be 1 white peg.

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Re: Barebones Mastermind Game

Toothless the Dragon 11 Feb 2014 21:51

It seems like you can cut down on a lot of variables and extra functions, just by skimming your code. Here's a few I've seen right off the bat, because I can't post much as I'm at school atm. :P

DelVar TDelVar GDelVar Rint(10rand(4→L1

///Replace with...

DelVar TDelVar GDelVar RrandInt(1,9,4→L1

Use randInt( instead of rand combined with other functions. It's designed to do this, and uses less bytes.

Re: Barebones Mastermind Game

Josiah W 11 Feb 2014 22:23

Actually, int(10rand(4 does the same thing as randInt(0,9,4. And they're the same size.

G is the amount of letters you have entered, K is either a number 0-9 if the numpad is pressed, or the keycode of the pressed key. R is the amount of red pegs (somehow, there is a way to cheat without this variable here). T is the amount of tries you have. X is just filler. L1 and L2 are the original sequence and the guessed sequence.

But then again, maybe I could combine the lists…

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Re: Barebones Mastermind Game

Mr Dino 12 Feb 2014 03:50

Actually, although int(10rand(4 and randInt(0,9,4 produce the same results, as Toothless said, randInt( is designed for integers, and so is faster, hardcoded in assembly for integers.
Timing
randInt(0,9,999
with a stopwatch gave me an average of 35.1 seconds (testing thrice).
Timing
int(10rand(999
with a stopwatch gave me an average of 39.2 seconds (testing thrice).
That's over a 10% increase in speed. Use randInt(), and test it yourself, please. We need a command timing section on our wiki, btw.
I'll try to add some of that if I have time.

Re: Barebones Mastermind Game

Mr Dino 12 Feb 2014 04:16

*and, I might add, my standard deviation was less than .03 seconds for each. I'm quite impressed with my reaction speeds… they're quite precise, if not accurate.
I would definitely use randInt( over the rand counterpart in cases of generating multiple random numbers, even though randInt( takes a byte extra, being a 2 byte token. Nearly all of TI's commands have some use, after all.

Re: Barebones Mastermind Game

Toothless the Dragon 12 Feb 2014 05:41

I… think I can confirm what Dino came up with.

Using the following program below, I calculated the average code timings for both randInt(0,9 and int(10rand.

DelVar L1
For(A,1,10
Disp A
DelVar B
startTmr→T
Repeat 10=checkTmr(T
B+1→B
int(10rand [[Repeat by replacing this line with randInt(0,9)]]
End
B→L1(A
End
Disp "TIMING:
Pause sum(L1)/dim(L1
"

From this, higher number equals faster. This means the code ran though many more times and thus, added more to the variable. From my results, int(10rand received a code timing of 247.9, and randInt(0,9 received a code timing of 263.27. So I got about a 6% increase in speed.

I think we DO have a code timings page Dino. But if we could create a program that could automate these timings, life would be a ton easier. :P

EDIT: Ta-da! We do! And we also have a few programs that automates code timing, whaddya know. http://tibasicdev.wikidot.com/timings

Confirmed using a second timing program that randInt( is faster.

startTmr→T
int(10rand(999
Disp checkTmr(T
"
Result: 21 (after testing thrice)

startTmr→T
randInt(0,9,999
Disp checkTmr(T
"
Result: 18 (after testing thrice)

Last edited on 12 Feb 2014 06:16 by Toothless the Dragon Show more

Re: Barebones Mastermind Game

MasterChief2552 12 Feb 2014 15:41

Due to the fact that this would only save a 3/100 second and it is only executed once (e.g. it is not in a loop), this optimization is useless.
Josiah, your code is really good, I do not think it could be optimized much… ;)

---

Wake me, when you need me.

Re: Barebones Mastermind Game

Xeda Elnara 13 Feb 2014 15:12

Wait, how is it useless? It doesn't add or remove any bytes size-wise, but it is faster. Even if it is only a tiny bit faster, that is still a tiny bit more efficient. He asked for improvements and this is an improvement :P

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Barebones Mastermind Game

MasterChief2552 13 Feb 2014 17:14

But improvements have to improve a program (I dont say?), and since this does not even save one second in terms of speed, it is a bit useless…
Optimization in terms of size (bytes) is always welcome, also if it only saves one bytes. Besides of size optimization there is of course speed optimization. But this has to be useful. There are places where speed optimizations arereally appreciated, for examples in loops. Even if a optimization only saves a split-second, if it is in a loop - where in fact it gets executed more than once (so it saves every loop iteration the split-second) - then I would call it an useful optimization.
But when the optimization only gets executed once (so if it is not in the body of a loop), and if it only saves a split-second, then it is not useful. The user could not see any differences.
Maybe I was a bit direct when saying this, but when you would call this an optimization, you also could do another thousand “useless“ optimizations, but all together it still would not change much.
But where I would look first in this program (regarding speed optimizations), is within the loops. :) ;)

---

Wake me, when you need me.

Re: Barebones Mastermind Game

Josiah W 13 Feb 2014 17:36

There you go.

He just summed it all up for you.

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Garfield (guest) 14 Feb 2014 00:01

…that's not a summary.

Re: Barebones Mastermind Game

Josiah W 12 Feb 2014 16:40

Thank you all for the kind words.

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Re: Barebones Mastermind Game

BatedMarlin 12 Feb 2014 21:19

I don't see the point of 15 tries. I can do it every time in 9 tries or less.

Re: Barebones Mastermind Game

Josiah W 12 Feb 2014 22:02

Oops, I meant 14!

And that was just to maximize the number of tries you could fit on the screen for reference.
I can usually solve it in less tries, too, but I did that mainly so others could have a chance, and I could fit it in, so why not?

And guys? Should this replace the example we have?, should it be an add-on to that page, or what?

At least, we could add a replacement with my WHITE peg formula?

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome