Optimizing some string stuffs

Forum Attachments

Optimizing some string stuffs

LemonDrop 04 Jul 2013 16:25

I was wondering if anyone can see any places in this peice of code from a larger program I made that could be compressed to save space:

ClrHome
Input Str0
If inString(Str0,"S:
Then
If length(Str0)>2+inString(Str0,"S:
Then
If inString(sub(Str0,inString(Str0,"S:"),length(Str0)-inString(Str0,"S:"))," 
Then
Disp "One"
Disp sub(Str0,inString(Str0,"S:")+2,inString(sub(Str0,inString(Str0,"S:"),length(Str0)-inString(Str0,"S:"))," ")-(inString(Str0,"S:")+2))
Else
Disp "Two"
Disp sub(Str0,inString(Str0,"S:")+2,length(Str0)-(inString(Str0,"S:")+1))
End
Else
Disp "Three
End
Else
Disp "Four
End

Thanks for any help

Re: Optimizing some string stuffs

Silver Phantom 04 Jul 2013 16:33

it looks like your doing

inString(Str0,"S:"

so much that you should just assign it to a variable, but i might just be reading the code wrong

---

The Silver Phantom welcomes you

Re: Optimizing some string stuffs

LemonDrop 04 Jul 2013 16:47

Oh yea I could do that. I just normally forget about variables because I tend not to use them much.

Re: Optimizing some string stuffs

Xeda Elnara 04 Jul 2013 16:55

Yes, this is a good tip ^ In code:

ClrHome
Input Str0
inString(Str0,"S:"
If Ans
Then
If 2+Ans<length(Str0
Then
If inString(sub(Str0,Ans,length(Str0)-Ans)," 
Then
Disp "One
Disp sub(Str0,Ans+2,inString(sub(Str0,Ans,length(Str0)-Ans)," ")-Ans-2
Else
Disp "Two
Disp sub(Str0,Ans+2,length(Str0)-Ans-1
End
Else
Disp "Three
End
Else
Disp "Four
End

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimizing some string stuffs

LemonDrop 07 Jul 2013 13:41

I've pretty much compressed it down really far but was wondering if theres any way to optimize the actual logic part of it to make it smaller. All it does it get the text after S: until it hits a space (or the string ends).

inString(Str0,"S:->X
length(Str0->Y
If XY>X+1
Then
inString(sub(Str0,X,Y-X)," ->Z
If Z
Then
Disp sub(Str0,X+2,Z)-(X+2
Else
Disp sub(Str0,X+2,Y-(X+1
End
Else
Disp "psX:err
End

Re: Optimizing some string stuffs

Xeda Elnara 07 Jul 2013 22:08

Okay, I have:

inString(Str0,"S:→X
If Ans
Then
inString(Str0," ",Ans
If not(Ans
1+length(Str0
sub(Str0,X+2,Ans-X-2
Else
"psX:err
End
Disp Ans
<<rest of code>>

The only case that doesn't take care of is when the string to display is 0-sized. Also, I noticed that from some of your code, you might not be familiar with the third argument of inString( (which is optional) that allows you to begin the search at a given location in the string. By default, it starts searching at the beginning of the string.

Anyways, my code should be a bit faster and it is 35 bytes smaller. I also wanted to point out a size optimisations, too:

Disp sub(Str0,X+2,Y-(X+1

If you break down the math manually, you get a smaller code that is also faster (this isn't always the case):

Disp sub(Str0,X+2,Y-X-1

Also, your other Disp had an extra closing parentheses in the wrong place.

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimizing some string stuffs

LemonDrop 08 Jul 2013 02:04

Lol wow I can't believe I didn't know about that third argument, thanks that helps a lot.

Re: Optimizing some string stuffs

Roguebantha 09 Jul 2013 03:25

Wow I didn't know about that third argument either, thanks Xeda! :D

---

Re: Optimizing some string stuffs

Xeda Elnara 09 Jul 2013 10:03

Cool, then I am really glad I could help! I use inString( frequently enough, so it is second nature to me :P It is great for parsing strings :)

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimizing some string stuffs

Roguebantha 09 Jul 2013 13:17

Yes, the other one that I use a lot is dim(54 which is great for parsing too.

---