String Input Validation

Forum Attachments

Summary:

I want to check if a string is a number. It takes about 10 seconds for a 10 character string, I'd like to cut that in half.

String Input Validation

Deoxal 30 Jun 2018 04:23

A valid String can have:

• a negation sign or subtraction at the beginning of the string
• A single decimal point
• All numerals

I've indicated the stack level in with the double stars to better see the nested loops and if-statements. I also commented the code quite extensively.

:2→G // Flag used to check if there is more than more than decimal point in the string
:1→A // 

:If sub(Str1,1,1)="-"                        **1** // Changes the first character of the string to a negation sign if it is a subtraction sign because they are different in TI-Bacic.
:Then
:"-­"+sub(Str1,2,length(Str1)-1)→Str1
:End                                         **0**

:If Str1="­-" or Str1="-." or Str1="­."        **1** // Checks for special cases
:Then
:0→X
:Return
:End                                         **0**

:If sub(Str1,1,1)="­-   // Skips the check on the first character if it is a negative sign
:2→A

:For(X,A,length(Str1))                       **1**
:0→F                   // Flag used to trigger return to the calling program if it is not set to 1
:0→Z                   // Looping variable used in conjunction with the repeat loop

:sub(Str1,X,1)→Str9  // Separates each character into another string

:If Str9=".                                  **2** // Checks if the character is a decimal point
:Then
:G-1→G
:1→F
:If G=0                                      **3** // Returns to calling program if there is more than one decimal point
:Then
:0→X
:Return
:End                                         **2**
:End                                         **1**

:Repeat F or Z>9                             **2**  
:prgmNUMTOSTR // turns Z into Str0

:If Str9=Str0 // Checks if the current value of Z is a numeral
:1→F

:Z+1→Z // Increases the number to check
:End                                         **1**

:If not(F                                    **2** // Returns to the calling program if the string is not a number
:Then
:0→X
:Return                                        
:End                                         **1**               
:End                                         **0**

---

4920616D204261746D616E

Last edited on 30 Jun 2018 04:33 by Deoxal Show more

Re: String Input Validation

Trenly 30 Jun 2018 05:50

This is what I came up with, although it probably can be further optimized. This is how it works:

1. Remove any trailing decimals, negative signs, or minus signs to prevent errors
2. If the first character is a minus sign, replace it with a negative sign
3. Replace all minus signs with negative signs. This way we don't have to check for minus signs, and don't get errors
4. Check for more than 1 decimal
5. Check the location of a negative
6. If the first negative is after the first character, count the string as invalid
7. Check for more than 1 negative
8. Go through the string, making sure all the characters are in the set "⁻.0123456789"
9. If the string is invalid, do what is in Label R
10. If the string is a number, do what is in Label E

Without Comments:

If sub(Str1,length(Str1),1)=".":sub(Str1,1,length(Str1)-1→Str1
If sub(Str1,length(Str1),1)="⁻" or sub(Str1,length(Str1),1)="-":sub(Str1,1,length(Str1)-1→Str1
If sub(Str1,1,1)="-":"⁻"+sub(Str1,2,length(Str1)-1→Str1
While inString(Str1,"-"
  sub(Str1,1,inString(Str1,"-")-1)+"⁻"+sub(Str1,inString(Str1,"-")+1,length(Str1)-inString(Str1,"-")→Str1
End
inString(Str1,"."→A
If inString(Str1,".",A+1:Goto R
inString(Str1,"⁻"→A
If (A≠1) and (A≠0):Goto R
If inString(Str1,"⁻",A+1:Goto R
DelVar A
For(E,1,length(Str1)
  If not(inString("⁻.0123456789",sub(Str1,E,1):1→A
  If A:length(Str1→E
End
If A:Goto R
Goto E
Lbl R
Return
Lbl E
//If it is a number, do this

With Comments:

If sub(Str1,length(Str1),1)=".":sub(Str1,1,length(Str1)-1→Str1
//removes a trailing decimal (Example: 5. becomes 5
//this prevents errors later, so is precautionary

If sub(Str1,length(Str1),1)="⁻" or sub(Str1,length(Str1),1)="-":sub(Str1,1,length(Str1)-1→Str1
//removes a trailing negative or minus to prevent errors

If sub(Str1,1,1)="-":"⁻"+sub(Str1,2,length(Str1)-1→Str1
//if the first character is a minus, replace it with a negative

While inString(Str1,"-"
  sub(Str1,1,inString(Str1,"-")-1)+"⁻"+sub(Str1,inString(Str1,"-")+1,length(Str1)-inString(Str1,"-")→Str1
End
//Change all the minus signs after the first character to negative signs
//This allows skipping a check, and prevents errors

inString(Str1,"."→A
//store the location of the first decimal, 0 if none
If inString(Str1,".",A+1:Goto R
//If there is more than 1 decimal, goto the label R

inString(Str1,"⁻"→A
//store the location of the first negative, 0 if none
If (A≠1) and (A≠0):Goto R
//if the first negative is not at the beginning, goto the label R
If inString(Str1,"⁻",A+1:Goto R
//if there is more than 1 negative, goto the label R

DelVar A
//create a flag
For(E,1,length(Str1)
//for every token in Str1
  If not(inString("⁻.0123456789",sub(Str1,E,1):1→A
  //test if it is in the string of valid characters
  //if it is not, set the flag
  If A:length(Str1→E
  //if the flag is set, skip further checks
End
If A:Goto R
//if the flag is set, goto the label R
//this is not inside the for loop to avoid memory leaks

Goto E
Lbl R
Return
Lbl E
//If it is a number, do this

Last edited on 30 Jun 2018 06:18 by Trenly Show more

Re: String Input Validation

Deoxal 30 Jun 2018 18:48

This all looks good except the trailing decimal part. I specifically need to be able to have Strings such as "123.". This is because I am using this subprogram in another program to do accuracy dependent arithmetic. If you are familiar with significant figures this will make sense. For example, "210 x 121 = 25000", but "210. x 121 = 25400". This is because "210" has 2 significant figures due to the trailing zero and "121" has 3 significant figures. When one number has fewer significant figures in a calculation you have to default to the one with fewer significant figures. However, "210." has 3 significant figures, which changes the answer to the calculation.

Could I erase the line of code that eliminates trailing decimals or would that break it?

---

4920616D204261746D616E

Last edited on 30 Jun 2018 18:50 by Deoxal Show more

Re: String Input Validation

Trenly 01 Jul 2018 01:27

It would make it error out on the check for two decimals, since it would see the decimal at the end and try to check for a second one outside the bounds of the string.

The easiest thing would be to set a flag and readd it after the double decimal check. I will update the code later.

I did notice a few other things about this code. It will still break if they have 2 decimals at the end of a string, or two negative signs at the end of a string if there are not any preceding decimals or negatives. This can be fixed by changing a few Ifs into Whiles

Show Code

DelVar D
//Create a flag
If sub(Str1,length(Str1),1)="."
//Check if the last character is a decimal
Then
sub(Str1,1,length(Str1)-1→Str1
//If the last character is a decimal, remove it
1→D
//If the last character is a decimal, set the flag
End

If sub(Str1,length(Str1),1)="⁻" or sub(Str1,length(Str1),1)="-":sub(Str1,1,length(Str1)-1→Str1
//Removes a trailing negative or minus to prevent errors

If sub(Str1,1,1)="-":"⁻"+sub(Str1,2,length(Str1)-1→Str1
//If the first character is a minus, replace it with a negative

While inString(Str1,"-"
sub(Str1,1,inString(Str1,"-")-1)+"⁻"+sub(Str1,inString(Str1,"-")+1,length(Str1)-inString(Str1,"-")→Str1
End
//Change all the minus signs after the first character to negative signs
//This allows skipping a check, and prevents errors

inString(Str1,"."→A
//store the location of the first decimal, 0 if none
If inString(Str1,".",A+1:Goto R
//If there is more than 1 decimal, goto the label R
If Dnot(inString(Str1,".")):Str1+"."→Str1
//If the flag is set, and there are no decimals already in the string, readd the decimal at the end

inString(Str1,"⁻"→A
//store the location of the first negative, 0 if none
If (A≠1) and (A≠0):Goto R
//If the first negative exists and is not at the beginning, goto the label R
If inString(Str1,"⁻",A+1:Goto R
//If there is more than 1 negative, goto the label R

DelVar A
//Create a flag
For(E,1,length(Str1)
//For every token in Str1
If not(inString("⁻.0123456789",sub(Str1,E,1):1→A
//Test if it is in the string of valid characters
//If it is not, set the flag
If A:length(Str1→E
//If the flag is set, skip further checks
End
If A:Goto R
//If the flag is set, goto the label R
//This is not inside the for loop to avoid memory leaks

Goto E
Lbl R
Return
Lbl E
//If it is a number, do this

Using While to fix a few bugs:

DelVar D
//Create a flag
While sub(Str1,length(Str1),1)="."
//Check if the last character is a decimal
sub(Str1,1,length(Str1)-1→Str1
//If the last character is a decimal, remove it
1→D
//If the last character is a decimal, set the flag
End

While sub(Str1,length(Str1),1)="⁻" or sub(Str1,length(Str1),1)="-":sub(Str1,1,length(Str1)-1→Str1:End
//Removes a trailing negative or minus to prevent errors

If sub(Str1,1,1)="-":"⁻"+sub(Str1,2,length(Str1)-1→Str1
//If the first character is a minus, replace it with a negative

While inString(Str1,"-"
sub(Str1,1,inString(Str1,"-")-1)+"⁻"+sub(Str1,inString(Str1,"-")+1,length(Str1)-inString(Str1,"-")→Str1
End
//Change all the minus signs after the first character to negative signs
//This allows skipping a check, and prevents errors

inString(Str1,"."→A
//store the location of the first decimal, 0 if none
If inString(Str1,".",A+1:Goto R
//If there is more than 1 decimal, goto the label R
If Dnot(inString(Str1,".")):Str1+"."→Str1
//If the flag is set, and there are no decimals already in the string, readd the decimal at the end

inString(Str1,"⁻"→A
//store the location of the first negative, 0 if none
If (A≠1) and (A≠0):Goto R
//If the first negative exists and is not at the beginning, goto the label R
If inString(Str1,"⁻",A+1:Goto R
//If there is more than 1 negative, goto the label R

DelVar A
//Create a flag
For(E,1,length(Str1)
//For every token in Str1
If not(inString("⁻.0123456789",sub(Str1,E,1):1→A
//Test if it is in the string of valid characters
//If it is not, set the flag
If A:length(Str1→E
//If the flag is set, skip further checks
End
If A:Goto R
//If the flag is set, goto the label R
//This is not inside the for loop to avoid memory leaks

Goto E
Lbl R
Return
Lbl E
//If it is a number, do this

Last edited on 01 Jul 2018 02:39 by Trenly Show more

Re: String Input Validation

Deoxal 01 Jul 2018 19:34

Ok, thanks for the help.

---

4920616D204261746D616E

Re: String Input Validation

lirtosiast 15 Oct 2018 05:03

I'm late, but this can be done efficiently (3 lines of code, less than 1 second). Here's the process:

1. If the length is at least 2, and there is a leading - or negation sign, ignore it. If the - is the only character in the string, it will not be ignored, and the string will fail step 3.
2. Use seq( to convert the string to a list, with 0 being invalid character, 1 being ., and 2-11 being digits.
3. Check that the list has no 0s, at least one number greater than 1, and less than two 1s.

As a routine that takes Str1 and returns boolean:

1<length(Str1) and inString("-⁻",sub(Str1,1,1
seq(inString(".0123456789",sub(Str1,X,1)),X,1+Ans,length(Str1
min(Ans)max(Ans>1) and 2>sum(Ans=1

This still errors on the empty string, but that's easy to fix.