Optimization for a newbie

Forum Attachments

Optimization for a newbie

Holomon (guest) 08 Jan 2013 21:43

I am fairly new to programming with TI-Basic and having created a few fairly simple but inefficient programs I decided to create a simple reaction game that has players press the corresponding number keys from a visual prompt. I used simple graphics with a window setting of (0,0) to (4,4) for this program as one optimization (I was originally using 9 pictures and recalling them as needed), however I would like feedback from an experienced group on how to optimize my program. [At the start of the program there is a very crude timer to give the player a chance to prepare]

:6→W
:0→S
:0→X
:0→Y
:0→R
:ClrHome
:While W>0
:For(V,1,100)
:End
:ClrHome
:W-1→W
:Output(4,8,W)
:End
:ClrDraw
:DispGraph
:Lbl A
:0→H
:ClrDraw
:randInt(1,3)→X
:randInt(1,3)→Y
:101-10Y+X→R
:Horizontal Y
:Vertical X
:While H<50
:getKey→K
:If K=R:Then:S+1→S:Goto A:End
:If K=105:Stop
:H+1→H
:End
:ClrDraw
:Disp S

Any feedback would be great thanks :)

Re: Optimization for a newbie

Roguebantha 08 Jan 2013 22:40

:DelVar SDelVar XDelvar YDelVar R
:ClrHome
:For(W,6,1,-1
:For(V,1,E2     (The small E)
:End
:ClrHome
:Output(4,8,W
:End
:ClrDraw
:DispGraph
:Lbl A
:ClrDraw
:randInt(1,3→X
:randInt(1,3→Y
:101-10Y+X→R
:Horizontal Y
:Vertical X
:For(H,0,50
:getKey
:If Ans=R:Then:S+1→S:Goto A:End    (This will cause a memory leak, so I suggest you find some other way to do this either without a goto, or without the wrapping loop.)
:If Ans=105:Stop
:End
:ClrDraw
:Disp S

---

Last edited on 08 Jan 2013 22:41 by Roguebantha Show more

Re: Optimization for a newbie

(account deleted) 08 Jan 2013 23:03

That is a creative idea. :)

ClrHome
For(W,1,6
Output(4,8,6-W
End
[Carry out the rest of your program]

---

Coffee + Radiohead = ^^

Re: Optimization for a newbie

Roguebantha 08 Jan 2013 23:27

Eh, I think that would go to fast for what he wants it to do. Also, it would work better like this, since you can use a fourth argument as the increment:
For(W,6,1,-1
Output(4,8,W
End

Actually, this code is a byte or so longer but probably faster.

---

Re: Optimization for a newbie

(account deleted) 08 Jan 2013 23:36

I did not know you could do that. :O

---

Coffee + Radiohead = ^^

Holomon (guest) 09 Jan 2013 07:08

Would an If with no End fix the memory problem? Creating a second variable T to compare against S would work if it did.

:Lbl A
:ClrDraw
:S→T
:randInt(1,3→X
:randInt(1,3→Y
:101-10Ans+X→R
:Horizontal Y
:Vertical X
:For(H,0,50
:getKey
:If Ans=R:S+1→S
:If Ans=105:Stop
:If S (not equal to) T:Goto A
:End
:ClrDraw
:Disp S

Holomon (guest) 09 Jan 2013 07:35

Actually this would fix the memory leak but not skip to the next location after a successful keypress but I don't mind that, at least it doesn't slow the game down. Thanks for the help and after reading some of the articles on the site I can optimize some of my other programs that are pretty hideous to look at or even understand. I will probably post my stopwatch program at some point (made without the internal timer) as it works fairly well.

:Lbl A
:ClrDraw
:S→T
:randInt(1,3→X
:randInt(1,3→Y
:101-10Ans+X→R
:Horizontal Y
:Vertical X
:For(H,0,50
:getKey
:If Ans=R:S+1→S
:If Ans=105:Stop
:End
:If S (not equal to) T:Goto A
:ClrDraw
:Disp S

burr 09 Jan 2013 09:14

:Repeat S=T
:ClrDraw
:S→T
:randInt(1,3→X
:Vertical Ans
:randInt(1,3
:Horizontal Ans
:101-10Ans+X→R
:For(H,0,50
:getKey
:If Ans=105:Stop
:S+(Ans=R→S
:End
:End
:ClrDraw
:S

Last edited on 09 Jan 2013 09:25 by burr Show more

Re: Optimization for a newbie

Xeda Elnara 09 Jan 2013 15:58

@Holomon: I would advise to use Return as opposed to Stop. If somebody calls your program from another program (like a shell), Stop will end all of the running programs whereas Return will go back to the program calling it.

---

47%? Take a look and try to imagine how cool 100% will be. This has won zContest 2011 and made news on TICalc. This compromise between Assembly and BASIC parses like BASIC and is fast like assembly. Grammer 2

Holomon (guest) 09 Jan 2013 16:53

@Xeda: That would be helpful actually as I plan to make an gui hub for my programs eventually.

Re: Optimization for a newbie

Xeda Elnara 09 Jan 2013 16:54

Cool! Then yes, definitely use Return :D

---

47%? Take a look and try to imagine how cool 100% will be. This has won zContest 2011 and made news on TICalc. This compromise between Assembly and BASIC parses like BASIC and is fast like assembly. Grammer 2