Optimize Me Quiz

Forum Attachments

Summary:

An optimization quiz of my own design.

Optimize Me Quiz

Josiah W 05 Jan 2013 03:16

Can you think of ways to optimize this? Whoever can reduce this by the most can start a new thread with another quiz. This is not important, I'm just testing other people's optimization skills.

PROGRAM:SAMPLE
:4→A
:8→B
:"*"→Str1
:Lbl AA
:getkey→K
:Output(A,B,Str1)
:If K=24
:B-1→B
:If K=25
:A-1→A
:If K=26
:B+1→B
:If K=34
:A+1→A
:If K=45 
:Then
:ClrHome
:Stop
:End
:Goto AA

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Re: Optimize Me Quiz

Mr Dino 05 Jan 2013 04:49

:4→A
:8→B
:Repeat K=45
:Output(A,B,"*
:getKey→K
:A+sum(ΔList(Ans={25,34→A
:B+sum(ΔList(K={24,26→B
:End
:ClrHome
:Stop // only necessary if you actually wanted to use Stop; letting the program run to the end of the code is the equivalent to Return, which has some minor differences.

Last edited on 05 Jan 2013 04:51 by Mr Dino Show more

Re: Optimize Me Quiz

Xeda Elnara 05 Jan 2013 14:18

@Josiah W: Typically Return is preferred to Stop. If a BASIC program tries to run your program, Stop will end both programs, but Return will return to the parent program. There are also issues with some assembly shells with programs that use Stop.

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Last edited on 05 Jan 2013 14:18 by Xeda Elnara Show more

Re: Optimize Me Quiz

The Cow 16 Jan 2013 17:37

I was thinking that if the "Return" is at the end of a program, it is not needed at all.

---

Fire Emblem for TI 83/4+ Progress: Demo: 75% Total: 40% Postponed indefinitely

Re: Optimize Me Quiz

Xeda Elnara 16 Jan 2013 18:10

Yep, that is true. Return is not needed if it is at the end of the program :)

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimize Me Quiz

Josiah W 05 Jan 2013 18:52

Good! Start a new thread, Mr Dino.

---

:ClrHome:Disp "HOW DOES A","MATHEMATICIAN","LOSE WEIGHT?
:Pause "
:Pause "BINOMIALS!
:Pause "(BUY NO MEALS)":ClrHome

Re: Optimize Me Quiz

simonalford42 05 Jan 2013 13:12

I have my own optimizing challenge:

:getdate->K
:text(57,67+4(10>Ans(2)),Ans(2
:text(57,87-4(10>Ans(3)),LK(1)-2000
:text(57,77,LK(3
:Pxl-On(60,85-4(10>LK(3
:Pxl-on(60,75

Basically, I want an optimized way to display the date neatly. I don't really care what you do with it, you could write a completely new program if it's smaller, but I'm interested in seeing if my optimized version of this is the best I can do.

Last edited on 05 Jan 2013 13:14 by simonalford42 Show more

Re: Optimize Me Quiz

Xeda Elnara 05 Jan 2013 14:13

I shall nom that code (I'm not really using the command :P).
First, note that Text() and Pxl-On() do not modify Ans. You can then optimise to save five bytes and you don't need LK (which uses 39 bytes of RAM):

:getDate
:Text(57,67+4(10>Ans(2)),Ans(2
:Text(57,87-4(10>Ans(3)),Ans(1)-2000
:Text(57,77,Ans(3
:Pxl-On(60,85-4(10>Ans(3
:Pxl-On(60,75

Even better though is that you can make Text() display multiple items and there is a token using the "." From the program editor, press [2nd][Y=][Left][3]. For this code, I will just use a period, though:

:getDate
:Text(57,67,Ans(2),".",Ans(1)-2000,".",Ans(3

But I think using a "-" or "/" looks nicer. And if you want it to be right adjusted:

:4sum(iPart(log(getDate→A
:getDate
:Text(57,82-A,Ans(2),"-",Ans(1)-2000,"-",Ans(3

It might just be easier to do something like this, though:

getDtStr(0
Text(57,95-4length(Ans),Ans

Start: 91 bytes + 39 bytes external variables
Opt1: 86 bytes, LK is not used, saving 39 more bytes
Opt2: 36 bytes
Opt3: 47 bytes + 18 bytes external variables, adds right-justification
Opt4: 18 bytes, adds right justification

:D 86% optimisation :3

Xeda112358 waits for Weregoose to optimise to -13 bytes
EDIT: Here is getDtStr( if you aren't familiar with it.

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Last edited on 05 Jan 2013 14:14 by Xeda Elnara Show more

Re: Optimize Me Quiz

simonalford42 05 Jan 2013 19:54

:95-4length(getDtStr(0
:Text(57,Ans,getDtStr(0

There, I optimized it one more byte :D

But wow!!! Your optimizationizationizing is amazing :O really though, that is utterly exhilarating to see 86% optimization. Thanks :)

Last edited on 05 Jan 2013 19:55 by simonalford42 Show more

Re: Optimize Me Quiz

Xeda Elnara 05 Jan 2013 21:17

That is actually one byte larger :P Remember that newlines use a byte and length() and getDtStr() are both two-byte tokens. All of the date/time commands are two byte tokens, I believe.

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimize Me Quiz

simonalford42 05 Jan 2013 21:36

Hehehe wooooow. Well… I'm learning :D

Optimize Me #2

Mr Dino 06 Jan 2013 03:54

I've got two, one in Axe and one in BASIC:
Axe
With Pics defined like this:
[stuff]→Pic1
[stuff]
[stuff]→Pic2
[stuff]
[stuff]→Pic3
[stuff]
[stuff]→Pic4
[stuff]

Pt-On(C*9+1,D*9+1,Pic1
Pt-On(E*9+1,F*9+1,Pic1
Pt-On(G*9+1,H*9+1,Pic2
Pt-On(I*9+1,J*9+1,Pic2
Pt-On(K*9+1,L*9+1,Pic3
Pt-On(M*9+1,N*9+1,Pic3
Pt-On(O*9+1,P*9+1,Pic4
Pt-On(Q*9+1,R*9+1,Pic4

*need help with this, I know you can For() loop this.
BASIC

ClrDraw
ZStandard
0→A
For(B,-10,10,ΔX)
e^(i.5×√(.5!/.5))*A+1→A
Pt-On(B,A)
End
End

*fuzzyness! This can be improved a lot with a different method.

Re: Optimize Me #2

simonalford42 06 Jan 2013 13:36

"CDEFGHIJKLMNOPQR→Str1
For(A,1,8
Pt-On(9expr(sub(Str1,2A-1,1))+1,9(expr(sub(Str1,2A,1))+1,Pic(int(.5(A+1
End

if that works I'm sure it can be optimized more. The only thing is, can Pics be defined like that, with an expression? 'Cause if not, I have no clue how to optimize it… Sorry, I have no clue about programming with Axe so this is all Basic-stuff.

And for the second one, I'm getting an ERR: DATA TYPE and I think it's because of the i. But anyway, it could be something like

ClrDraw
ZStandard
DelvarA1+Ae^(i.5×√(.5!/.5→Y1    //  use the e^( token here if not already being used
DispGraph

Last edited on 06 Jan 2013 13:37 by simonalford42 Show more

Re: Optimize Me #2

Mr Dino 06 Jan 2013 13:47

The i.5 was supposed to be i * .5 with implicit multiplication. I haven't tested it; if it gives errors, move the i after the .5 - .5i
It can even be optimized more! Ignore the i; try this:
.5×√(.5!/.5
And see what you get. You'll be extremely suprised. Then use [insert secret name]'s awesome formula and it simplified easily.

Re: Optimize Me #2

simonalford42 06 Jan 2013 14:55

:ClrDraw
:Zstandard
:Horizontal 1

?

Re: Optimize Me #2

Xeda Elnara 06 Jan 2013 15:23

First, gamma of .5 is sqrt(pi)/2, so

√(.5!/.5)=√(.5!2)=√(√(pi))

Now e^(i.5√(√(pi)))A+1→A can be brought to the following, for those not familiar with the relationship between Euler's number and i:

.5√(√(pi
1+Acos(Ans)+iAsin(Ans→A

Because of this, your code won't work (it will throw errors because it doesn't let you use imaginary numbers for points— we don't have a 4D grapher :P)

If you are interested, though, replace Pt-On(B,A) with Pt-On(imag(Ans),real(Ans :)

An interesting formula to optimise is also:
e^(i.5(.5!/.5)^2)*A+1→A
e^(i.5(sqrt(pi)/.5)^2)*A+1→A
e^(i.5(pi/4)/.25)*A+1→A
e^(i.5pi)*A+1→A
(cos(.5pi)+isin(.5pi))*A+1→A
1+iAsin(pi/2→A
1+iA→A

That will alternate between 1,1+i,i,0 and continue that loop. In a For() loop, that can be simplified to simply 1+iAns

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimize Me #2

Xeda Elnara 06 Jan 2013 15:39

Oh, and for your Axe code, I am assuming that isn't the whole code and you are incrementing the variables or decrementing in some other part of the code? If so, I can definitely help with that: First, use a buffer to hold the coordinates. I will use L1. Initialise them all to 1. Now, whenever you increment a variable, add 9, when you decrement, subtract 9. Adding or subtracting is smaller and much faster than multiplication.

To users not familiar with Axe: Axe is a compiled language, unlike BASIC, so sometimes source code that is larger might produce a smaller compiled code.

Anyways, to continue, I am assuming all of your Pic variables are 8x8 sprites? If so, then you can simply do something like this:

[sprite1]→Pic1
[sprite2]
[sprite3]
[sprite4]
Fill(L1,16,1    ;16 bytes at L1 are loaded with "1"
<<whatever code>>
L1-1→A
Pic1-8→B
For(4)         ;Loop 4 times
Pt-On({A++}r,/256,B+8→B
Pt-On({A}r,/256,B
End

I haven't actually tested it, so that could be wrong (I am not too accustomed with the language). Note that the "r" is the one found in the Angle menu. I hope it works ._. Runer112 on Omnimaga could probably make that code in -13 bytes (he is basically Weregoose for Axe).

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Optimize Me #2

Mr Dino 06 Jan 2013 18:44

I actually wasn't using the sqrt there; I was using the .5 root, which is actually to the power of 2. That would've simplified to pi.