SGM_Self Generating Maze - (ideas/problems)

We're glad you came by, but you might find what you're looking for elsewhere. TI-Basic Developer is not the site it once was. While its information on commands and other calculator features remains almost second-to-none, its forum, archives, and even hosting service, Wikidot, have been decaying for years. The calculator community would love to see what you're working on, or help you in your next coding adventure, but TI-Basic Developer is no longer the place to do it. Instead, you should head over to Cemetech (primarily American) or TI-Planet (primarily international). Both are active, well-established forums with their own archives, chatrooms, reference material, and abundant coding tools and resources. We'll see you there, we hope.

Forum Attachments

Summary:

!>HOT<!

SGM_Self Generating Maze - (ideas/problems)

Gaptosm Meyer 27 Apr 2018 15:03

Hello there,

im not a good developer so i will let u guys do something out of this ;)
Without further, here my idea and how i think its going to work.

- First we will set a PXL at a random position on the screen.

- Then we will set a random direction 1-4.

- Before a new PXL is placed in the random direction, we will test as followed. ▓=Pixel, ▒=Testet Area, ´=Just a placeholder

▒▒
▒▒▓ :if D=1
▒▒

▒▒▒
▒▒▒ :if D=2
´ ▓

´ ▒▒
▓▒▒ :if D=3
´ ▒▒

´ ▓
▒▒▒ :if D=4
▒▒▒

- In this case there will always be a gap between placed PXL.

- If there is no Pixel, only then there will be placeds a new Pixel.

___

I tried it with for loops, with repeats etc. and so on. But it does not work at all.
But im not a good developer.

I hope u could find a way how to solve.

Re: SGM_Self Generating Maze - (ideas/problems)

Trenly 27 Apr 2018 17:20

Because the graph screen likes to mess with X and Y variables, its best not to use them when working with pixel coordinates. To get around this I will V instead of X, and W instead of Y. Therefore V is the pixels X position, and W is the pixels Y position. I will use P as the indicator that the test area is blank

0→P
If D=1
Then
⁻2→L
⁻1→R
⁻1→U
1→D
End
If D=2
Then
⁻1→L
1→R
⁻2→U
⁻1→D
End
If D=3
Then
1→L
2→R
⁻1→U
1→D
End
If D=4
Then
⁻1→L
1→R
1→U
2→D
End
For(θ,W+L,W+R
For(E,V+U,V+D
P+Pxl-Test(E,θ)→P  //note that Pxl-Test is in Y,X not in X,Y
End
End
//P will contain 0 if no pixels were on, or it will contain the number of pixels that were on

This should work, but I haven't tested it. L, R, U, D are used for left right up down values to test around the pixel. If D is 1 we test 2 pixels left to 1 pixel left and 1 pixel above to 1 pixel below. If D is 2 we test 1 pixel left to 1 pixel right and 2 pixels above to 1 pixel above. If D is 3 we test 1 pixel right to 2 pixels right and 1 pixel above to 1 pixel below. If D is 4 we test one pixel left to one pixel right and 1 pixel below to 2 pixels below.

I recommend looking into how nested For( loops work so you can better undersand what I am trying to do. The best way to visualize them may be to use the code below. Try changing some of the numbers to see how it effects the loop.

For(θ,10,40
For(E,10,25
Pxl-Change(E,θ
End
End

Re: SGM_Self Generating Maze - (ideas/problems)

kg583 28 Apr 2018 01:59

Here's a maze generator I made ages ago for the CSE/CE. A lot of the ideas you are considering are implemented in it:

0→Xmin:264→Xmax
0→Ymin:164→Ymax
AxesOff
For(Z,0,Ymax+2,2
Horizontal Z
End
Pt-Off(Xmax,2
Pt-Off(0,162
2→A:2→B:­3→E:2→F:1→I
ClrList L₁
Repeat K=45
getKey→K
If I=1
randIntNoRep(1+(D=2),4-(D=3),4-(D=3)-(D=2→L₁ \\Random seed; speeds up generation by not worrying about already checked directions
L₁(I→D
Pt-Off(B,Ymax-A
If D=1 and A≠2:Then
pxl-Test(A-5,B→P     \\Tests for a lack of pixel in desired direction
A-5Ans→A               \\Moves the drawer
Pt-Off(B,Ymax-Ans-2P       \\Draws
End
If D=2 and A≠162:Then
pxl-Test(A+5,B→P
A+5Ans→A
Pt-Off(B,Ymax-Ans+2P
End
If D=3 and B≠2:Then
pxl-Test(A,B-5→P
B-5Ans→B
Pt-Off(Ans+2P,Ymax-A
End
If D=4 and B≠262:Then
pxl-Test(A,B+5→P
B+5Ans→B
Pt-Off(Ans-2P,Ymax-A
End
1+Inot(P→I         \\Count of how many directions the drawer has tried
Pt-Off(B,Ymax-A
If I>dim(L₁:Then
Repeat Qnot(P
E+5→E        \\Moves the "main path" point down
F+5(Ans=167→F         \\Moves the "main path" point right if the column is exhausted
If F=267:Goto 1          \\Exit condition
E≠167:EAns+2not(Ans→E
pxl-Test(Ans,F→P
pxl-Test(E-5(E≠2),F)+pxl-Test(E+5(E≠162),F)+pxl-Test(E,F-5(F≠2))+pxl-Test(E,F+5(F≠262→Q     \\Keep moving the "main path" point until it arrives somewhere a path could spawn from
End
E→A:F→B:1→I
End:End

One important thing about this generator is that it does not use a stack or queue or other list structure to keep track of its progression. Once a branch of the maze boxes itself in, the "drawer" returns to last point it left the "main path", and starts again. The "main path" point moves across the screen as the maze is generated, and can fill the entire screen in about ten minutes.
I went through heavy optimization for this, so if any bit looks weird or hard to understand I'll do my best to explain it.

---

The solution to a complex problem is often a simple answer.

Last edited on 28 Apr 2018 05:35 by kg583 Show more

Re: SGM_Self Generating Maze - (ideas/problems)

(account deleted) 28 Jun 2018 22:38

Can you make the CSE/CE version for the 84+?

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Re: SGM_Self Generating Maze - (ideas/problems)

Myles_Zadok 28 Jun 2018 22:49

I think you should try converting it yourself. You will learn a lot more that way. All you really have to do, just glancing at the code, is change the values that involve graph screen dimensions and coordinates. I'm pretty confident you can do that.

Re: SGM_Self Generating Maze - (ideas/problems)

(account deleted) 28 Jun 2018 22:52

I'll try, thanks for the inspiration. :)

EDIT: There is a problem with this line though, I get a Argument error:

randIntNoRep(1+(D=2),4-(D=3),4-(D=3)-(D=2→L₁

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Last edited on 28 Jun 2018 23:19 by (account deleted) Show more

Re: SGM_Self Generating Maze - (ideas/problems)

kg583 29 Jun 2018 01:35

I think the problem lies in the fact that for the version of randIntNoRep( for grayscale TI-84+, there is no optional [numelements] argument. This was probably introduced with OS 2.53, though I'm not sure. The wiki page needs to be updated to address this incompatibility.

To actually solve the problem, I'd suggest reading the wiki page and adapting the old routine to fit this task. Shouldn't be too difficult (though it will be a few more bytes).

---

The solution to a complex problem is often a simple answer.