Help with scrolling lists

We're glad you came by, but you might find what you're looking for elsewhere. TI-Basic Developer is not the site it once was. While its information on commands and other calculator features remains almost second-to-none, its forum, archives, and even hosting service, Wikidot, have been decaying for years. The calculator community would love to see what you're working on, or help you in your next coding adventure, but TI-Basic Developer is no longer the place to do it. Instead, you should head over to Cemetech (primarily American) or TI-Planet (primarily international). Both are active, well-established forums with their own archives, chatrooms, reference material, and abundant coding tools and resources. We'll see you there, we hope.

Forum Attachments

Summary:

help with making scrolling lists on the graph screen

Help with scrolling lists

Silver Phantom 06 Sep 2012 02:32

Hello,
I need help with making scrolling lists on the graph screen. the multi page kind is what i want. I want it to be a changeable list, like contacts. all i have right now is the program reading a string and takes whatever is between two comma and put it in one line and put the next in another, etc. i can only fit 4 per page (don't ask why). every time it goes through 1 option on the string, it adds one to a variable. i also have the getkey know where it is by adding or subtracting one from another variable (P) (option 1 is 1 and option 2 is 2). if the getkey variable tracking thingy is past 4, then it sets it to 1 and sets a third variable (T) to one more than it was. I know how to track which option the player chose (T*P=option number), but what i need help with is the multiple page changing.
if you don't understand what i just asked for or explained, feel free to ask.

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Mr Dino 06 Sep 2012 03:10

If you don't mind using Str variables rather than the traditional optimization of Ans, try this:
A=# of pages
Str1-StrA are the individual menus, with the title indicating # of pages, current page, actual title information, etc.
Start off on Str1, and change to Str2 if the user presses [RIGHT] or something, and etc.

Here's my custom menu program code for the homescreen: (It's kind of long, so I've tried commenting. If you don't understand it, ask me!)

:1→B  // will always start out on page 1
:Lbl 1          // I hate using Labels. But this is the fastest method, and there's only 1
:If B=1
:Str1
:If B=2
:Str2
:If B=3
:Str3             // you get the picture. All the way to Str0 based on A
......
:If B=A
:StrA
:ClrHome
:Output(1,1,Ans
:length(Ans)/16          // number of lines in this particular menu
:If fPart(Ans
:1+iPart(Ans
:Ans→D
:2→X
:Ans→Y
:Repeat C=21 or Ans      // 21 being [2nd], how the user picks their choice. And Ans being if they switched the page.
:Output(X,2," " //space
:Output(Y,2,">
:Repeat Ans
:getKey→C
:Y→X
:Y-(A=25)+(A=34→Y
:2(Y>D)+D(Y≤1)+Y(Y≤D and Y>1→Y    // scrolling! I was thinking of optimizing that with remainder( but I never did it.
:If C=21
:X-1→X                //setup X to the choice #.
:max(1,min(A,B+(C=26)-(C=24→B               // No scrolling. It just stops them from moving further
:max(C={24,26    // if C=24 or 26, Ans will be 1. Otherwise, it will be 0, and it will loop over
:End
:If C=21
:Return
:Goto 1   // If the page changed

Last edited on 06 Sep 2012 03:14 by Mr Dino Show more

Re: Help with scrolling lists

Silver Phantom 06 Sep 2012 21:55

i like what you did, but i would like it all to be on one string and i just realized my option locator thing doesn't work(all i need is for it to calculate the remainder if it can get option number divided by 4 and then the whole number is page and decimal is which option on the page(i can do that)).
here's the part of the code dealing with displaying the options. oh, i just need a changing menu
the string looks like this:
",(info), , (info) , ,(info),"

:0→L
:0→T
:Repeat 0=length(Str3) or L=4     //L is the limit
::L+1→L
::inString(Str3,",",T+1)→K
::inString(Str3,",",K+1)→T
::Text(-5+12L,7,sub(Str3,K+1,T-K-1))
:End
:Text(7,2,">"
:1→R             //option locator
:0→X
:Lbl 9
::Repeat X=25 or X=24 //i had other stuff for the menu, but not related to this
:::getkey→X
::End
:End
:If X=34:Then
::If L=1 or L=0:then
:::goto 9
::End
::Text(12R-5,2," "   //gets rid of >
::If R=L:then    //If the last position is the last option, then
:::1→R            //goto first option
::Else
:::R+1→R         //else goto the next one
::End
::Text(12R-5,2,">"
::Goto 9
:End
:If X=25:Then
::If L=1 or L=0:then
:::goto 9
::End
::Text(12R-5,2," "   //gets rid of >
::If R=L:then    //If the last position is the first option, then
:::L→R            //goto last option
::Else
:::R-1→R         //else goto the previous one
::End
::Text(12R-5,2,">"
::Goto 9
:End

i just can't think of a efficient way to make it change page after option 4

---

The Silver Phantom welcomes you

Last edited on 06 Sep 2012 21:56 by Silver Phantom Show more

Boba.Foxx (guest) 08 Sep 2012 01:18

OOH OOOH
I wrote something similar to this a while back last year
It scrolled up and down, paged left and right.
It was basically a schedule, although you'd have to go into the program to edit the strings.
I got it to loop and left in functionality for more pages
I left my calculator in my locker (Silly me :p), I'll check it then and if it's still on there, then I'll post it.

Sidenote: what's the tag on this forum for the code blocks?

Mr Dino 08 Sep 2012 02:04

The tag for code blocks :

[[code]]
insert the code here
[[/code]]

And please find your calculator and post your code here! I'm very interested in how you managed the scrolling - obviously Disp could be used to scroll down, but scrolling up would require a complete redraw, slowing the program… I want to know how you did it.

Last edited on 10 Sep 2012 00:08 by Mr Dino Show more

Pandoras Fox 08 Sep 2012 14:42

IIRC, I just had 4 or 5 strings that were all multiples of 16 in length, and I just used the sub( command with output.

Silver Phantom 08 Sep 2012 21:30

i would really like to see it.
will it be ok with you if i alter some of it to fit my program?

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Xeda Elnara 09 Sep 2012 20:46

Here is a program I wrote up waiting for laundry to finish :) Feel free to use or modify the code. Basically, if you remove the first two lines, H is the height of the list and Str1 contains the list. Commas separate each element and E starts a header. In this case, it is the exponential E ([2nd][,]). It looks like a regular E, here, though. Basically, it stores the location of each sub menu and each menu item into L1 and L2. This way, it can quickly find and display menu items. This code lets you use UP/DOWN to scroll through the list (which loops) and RIGHT/LEFT to change pages. H should be an integer greater than 0 and less than 8 (so 1,2,3,4,5,6,7). I plan to modify this to work on the graph screen to make it look much nicer. I made a program five or six years ago that had a great graph screen menu like this, but it never supported multiple pages or variable sized strings.

:3→H
:"EHEADER1,HELLO,WORLD,THIS,IS,A,LIST,THAT,SCROLLS,EHEADER2,ANOTHER,LIST?!,EHEADER3,THIS,WORKS,PRETTY,WELL,I,THINK→Str1
:length(Str1→B
:{1→L1
:Ans→L2
:For(A,1,B
:1+inString(Str1,",",A
:If Ans=1
:B+2
:Ans→A
:A→L1(1+dim(L1
:End
:For(A,1,B
:1+inString(Str1,"E",A
:If Ans=1
:B+2
:Ans→A
:A+1→L2(1+dim(L2
:End
:dim(L1→C
:dim(L2→D
:2→B
:Repeat A=105
:ClrHome
:C-sum(L1≥L2(B
:If B=1
:Ans+1
:Ans→E
:sum(L1≤L2(B+1
:Ans-1→F
:DelVar GDisp sub(Str1,1+L1(E),L1(E+1)-2-L1(E
:Repeat A=26 or A=24 or A=105
:For(A,1,H
:Output(A+1,2,"               
:End
:For(A,1+E+G,E+G+H
:A-E-1→I
:F-E
:E+1+round(AnsfPart(I/Ans),0
:Output(1+A-E-G,2,sub(Str1,L1(Ans),L1(Ans+1)-1-L1(Ans
:End
:Repeat Ans
:getKey→A
:End
:G+(A=34)-(A=25
:If Ans≥F-E
:0
:If Ans<0
:F-H+B-1
:Ans→G
:End
:B+(A=26)-(A=24
:If Ans≥D
:2
:If Ans<2
:D-1
:Ans→B
:End

Here is a screenie:

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Last edited on 11 Sep 2012 16:29 by Xeda Elnara Show more

Re: Help with scrolling lists

Silver Phantom 09 Sep 2012 21:50

this is awesome. is it required that there be header each page? also if i were to alter it to the point in which it fits on a graph, will the new limit be however pixels on the screen divided by 6 minus 6? and is the list changing per page and how will I know that menu item is a certain number?

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Xeda Elnara 09 Sep 2012 22:28

is it required that there be header each page?

Currently, yes, it requires a header, but you can modify the program to not need one.

also if i were to alter it to the point in which it fits on a graph, will the new limit be however pixels on the screen divided by 6 minus 6?

int(64/6)-1, so 9 is the limit. However, if you remove the header, that can be 10

is the list changing per page

No, it is all precalculated. Basically, the program checks which section of L1 corresponds to the current page and only uses that section.

how will I know that menu item is a certain number?

To figure out which menu item is a certain number, you can basically do this:

B-1 is the page number (B = 2 means the first page, B = 3 means the second page)
G is the current item on the page at the top of the list (first element corresponds to G=0
E is where the current page starts in L1

So E-B+1+G is the value that corresponds to the menu item.

EDIT: Also, I modified the code that I originally gave. The original code had:

:G+(A=34)-(A=25
:If Ans≥F-1
:0

But should have been:

:G+(A=34)-(A=25
:If Ans≥F-E
:0

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Last edited on 09 Sep 2012 22:31 by Xeda Elnara Show more

Re: Help with scrolling lists

Silver Phantom 11 Sep 2012 02:02

i cant seem to scroll up on page 2 past element 1.
anyway, when it's put on a graph, it looks beautiful.

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Xeda Elnara 11 Sep 2012 16:33

I am not sure what the issue is, it works for me. Also, I found another issue when I was checking this out:

I changed this:

:If Ans<0
:F-H+1

To this:

:If Ans<0
:F-H+B-1

And now scrolling backwards works better on previous pages.

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Help with scrolling lists

Silver Phantom 11 Sep 2012 17:05

It works now due to that

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Silver Phantom 11 Sep 2012 14:19

Wouldn't it be E-B+2+G

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Xeda Elnara 11 Sep 2012 16:35

Yes, you could do that. I was indexing at zero instead of 1. Zero-indexing lends some optimisations in certain cases. For example, using not( to test if the first item as selected instead of "=1" for 1-indexing. Example:

E-B+1+G
If not(Ans
Goto 1
If Ans=1
Goto 2
If Ans=2
Goto 3
...

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Boba.Foxx (guest) 11 Sep 2012 15:01

Couldn't you use

Augment(L2,{A+1) -> L2

Instead of:

A+1→L2(1+dim(L2

Boba.Foxx (guest) 11 Sep 2012 15:04

Also, how many spaces are in

:Output(A+1,2,"

Re: Help with scrolling lists

Xeda Elnara 11 Sep 2012 16:23

There are 15 spaces, but that can be adjusted as needed

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Help with scrolling lists

Xeda Elnara 11 Sep 2012 16:25

Yes, indeed it can. I cannot remember why I got in the habit of using the latter method, but I think it has to do with how much memory Ans will use. For example, with the method I used, Ans uses 18 bytes, whereas with the other method, Ans uses 9 plus the dimension of the list times 9. So as L2 grows, Ans will consume 9 more bytes after that line of code.

But I still prefer the smaller method using augment( though :D

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Help with scrolling lists

Silver Phantom 11 Sep 2012 17:09

Do you mind Pointing out the part with the header?

---

The Silver Phantom welcomes you

Re: Help with scrolling lists

Xeda Elnara 11 Sep 2012 17:15

Hmm, should I just rewrite it without the header?
This displays it:

:DelVar GDisp sub(Str1,1+L1(E),L1(E+1)-2-L1(E

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: Help with scrolling lists

Silver Phantom 11 Sep 2012 19:24

Oh, I thought it was more than that for the header.

---

The Silver Phantom welcomes you