Maze Questions

Forum Attachments

Summary:

This thread exists because I have a few questions I'd like to ask concerning my maze thingy thingy. I'm not sure this thread is in the perfect place, but oh well.

Maze Questions

Acro 25 Jan 2008 23:19

Okay. I have a simple, six-level maze game based off of the collision detection code from this site. I've stored each level as it's own matrix, and, following the making maps codes, have created the mazes on each level. As part of my question, I'm going to display the map for level 2 of my game.

[[1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1]
[1,0,0,0,0,0,0,0,0,0,1,0,0,0,1,1]
[1,0,1,1,1,1,1,1,1,0,1,0,1,0,1,1]
[1,0,1,0,1,0,0,0,1,0,1,0,1,0,1,1]
[1,0,1,0,0,0,1,0,1,0,1,0,1,0,0,0]
[1,0,1,1,1,1,1,0,1,0,1,0,1,0,1,1]
[1,0,0,0,0,0,0,0,1,0,0,0,1,0,1,1]
[1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1 store [B]

so. I was wondering. how could I make some 1's move around or maybe disappear and reappear? The only problem i can see is making it so that when a 1 disappears, the calculator doesn't try to read it as a 1 and not a 0.

Re: Maze Questions

burr 26 Jan 2008 06:08

First off, when you say you've stored each level as it's own matrix, are you talking about matrix variables (i.e., [A], [B], [C], etc.)? If that's what you're doing, I would recommend instead just storing each matrix value to the same variable:

:If L=1:<matrix code>  // level 1
:If L=2:<matrix code>  // level 2
:If L=3:<matrix code>  // level 3
:Ans→[B]

As for the second question, just try random locations, and once you have found an open spot (i.e., a zero), then store zero to the old spot and one to the new spot. It would be something like this (everything after the //'s is a comment):

:randInt(1,8→Y  // find random Y coordinate
:randInt(1,16→X  // find random X coordinate
:If [B](Y,X:Then  // the spot is a wall
:randInt(1,8→S  // find new random Y coordinate
:randInt(1,16→T  // find new random X coordinate
:If not([B](S,T:Then  // the new spot is empty
:1→[B](S,T  // set the new spot to a wall
:0→[B](Y,X  // set the old spot to empty
:End:End

Note that you can optimize this code further using some more advanced concepts (in particular, self-modifying code and Ans). This might be difficult to understand for you, but it's always nice to know about other ways to do things.

:"1+{int(9rand),int(17rand→u
:u→L1:If [B](Ans(1),Ans(2:Then
:u:If not([B](Ans(1),Ans(2):Then
:1→[B](Ans(1),Ans(2
:0→[B](L1(1),L1(2
:End:End

Re: Maze Questions

Acro 26 Jan 2008 17:29

Gotcha! Okay, that makes perfect sense. (the first one, not the one with the L1's… i'm not that great yet…)
Thanks burr!

Re: Maze Questions

DarkerLine 26 Jan 2008 18:14

Your random number generating code in the last example is off — it's generating numbers 1-9 and 1-17 instead of 1-8 and 1-16.

To go even further:

:1+int({8,16,8,16}rand(4→L1
:[B](Ans(1),Ans(2→T
:[B](L1(3),L1(4→[B](L1(1),L1(2
:T→[B](L1(3),L1(4)

For the record, it's not self-modifying code if it doesn't self-modify. That's just using an equation variable.

Last edited on 26 Jan 2008 18:15 by DarkerLine Show more

Re: Maze Questions

burr 26 Jan 2008 18:28

Yeah, you're right. I wrote that post right before bed, and didn't bother checking the code on my calculator — that's the laziness in me :D

Re: Maze Questions

Anonymous (71.205.96.x) 26 Jan 2008 18:42

Acro here— too lazy to sign in.

Now, when I inputted burr's

:randInt(1,8→Y 
:randInt(1,16→X  
:If [B](Y,X:Then 
:randInt(1,8→S 
:randInt(1,16→T  
:If not([B](S,T:Then  
:1→[B](S,T
:0→[B](Y,X 
:End:End

after the level matrix and before the actual collision detection code I used

:For(Y,1,8
:For(X,1,16
:If Ans(Y,X
:Output(Y,X,1
:End:End
:Repeat 30=abs(K-75
:getKey→K
:If max(Ans={24,25,26,34
:Output(A,B," // 1 space
:A-(Ans=25 and A>1 and not([A](A-(A>1),B)))+(Ans=34 and A<8 and not([A](A+(A<8),B→A
:B-(K=24 and B>1 and not([A](A,B-(B>1))))+(K=26 and B<16 and not([A](A,B+(B<16→B
:Output(A,Ans,"X
:End

The

:If Ans(Y,X

was giving me a syntax error. I was reading one of hedidit's posts, and he was talking out how the Ans have to go.

So, do they just go, or are they replaced?

Re: Maze Questions

burr 26 Jan 2008 18:45

That Ans is referring to the matrix variable, so you would just use that instead of Ans.

Re: Maze Questions

Acro 26 Jan 2008 19:10

So I would use the level matrix as the Ans substitute? Is that wot yer saying?

Re: Maze Questions

burr 26 Jan 2008 19:12

Yeah, that's what I'm saying.

Re: Maze Questions

Acro 26 Jan 2008 20:21

Oke-doke. Thanks!

edit: I replaced all the Ans with the first level's matrix, and I got a DATA TYPE error right at the end of

:If max(Ans={24,25,26,34

Of course, the Ans is actually matrix [A].

Last edited on 26 Jan 2008 20:30 by Acro Show more

Re: Maze Questions

Acro 27 Jan 2008 21:27

So what does that error mean? I can't see a problem with

:If max([A]{24,25,26,34

Last edited on 27 Jan 2008 21:27 by Acro Show more

Re: Maze Questions

burr 27 Jan 2008 21:33

The max(Ans={24,25,26,34 goes with the getKey→K on the line before it. max(Ans={24,25,26,34 is an optimized way of checking for the four arrow keys. The reason that it's giving you a DATA TYPE error is because you can't multiply a matrix by a list. You can, however, multiply individual elements of a matrix by a list, but that's something completely different.

Re: Maze Questions

Acro 27 Jan 2008 21:59

So i just keep it as Ans, then?

Edit: I changed it to Ans, gave me a data type error on

A-(Ans=25 and A>1 and not([A](A-(A>1),B)))+(Ans=34 and A<8 and not([A](A+(A<8),B→A

The Ans was changed to [A], and that was what was highlighted. I then changed that back to Ans. Then it highlighted the [A] (ans below) in

:Output(A,Ans,"X

So i changed that to Ans as well. Now, it just a the character moving through the maze without any crazy walls or anything. :(

Last edited on 27 Jan 2008 22:13 by Acro Show more

Re: Maze Questions

burr 27 Jan 2008 22:31

The problem is that I don't know what your current code looks like. If you can, could you please post it in its entirety?

Re: Maze Questions

Acro 27 Jan 2008 23:16

Yessir.

:ClrHome
:4→A:8→B
:[[Matrix]]→[A]
:For(Y,1,8
:For(X,1,16
:If Ans(Y,X
:Output(Y,X,1
:End:End
:Repeat 30=abs(K-75
:getKey→K
:If max(Ans={24,25,26,34
:Output(A,B," // 1 space
:A-(Ans=25 and A>1 and not([A](A-(A>1),B)))+(Ans=34 and A<8 and not([A](A+(A<8),B→A
:B-(K=24 and B>1 and not([A](A,B-(B>1))))+(K=26 and B<16 and not([A](A,B+(B<16→B
:Output(A,Ans,"X
:End

That's precisly what it looks like now.

Re: Maze Questions

burr 28 Jan 2008 00:42

Well, that's the code from the movement page, and I know that works. The only thing I can think is that you could try changing If Ans(Y,X to be If [A](Y,X.

Re: Maze Questions

Acro 28 Jan 2008 01:31

Mmkay.. Oops! That's what it is in the program.

Re: Maze Questions

burr 28 Jan 2008 01:48

So, you don't have any problems with the program?

Re: Maze Questions

Acro 28 Jan 2008 03:49

The numbers don't disappear and reappear.

Re: Maze Questions

burr 28 Jan 2008 05:11

What numbers are you talking about? You can't walk through the walls (the 1's), so those should never disappear. It sounds like your code is different than what you posted, and if that's the case, I would like you to post your code.

Re: Maze Questions

Acro 28 Jan 2008 05:44

Its the same code, but… oh crap! I totally forgot:

:4→A:8→B
:[[matrix]]→[A]
:randInt(1,8→Y
:randInt(1,16→X
:If [A](Y,X:Then
:randInt(1,8→S
:randInt(1,16→T
:If not([A](S,T:Then
:1→[A](S,T
:0→[A](Y,X
:End:End
:For(Y,1,8
:For(X,1,16
:If Ans(Y,X
:Output(Y,X,1
:End:End
:Repeat 30=abs(K-75
:getKey→K
:If max(Ans={24,25,26,34
:Output(A,B,"  
:A-(Ans=25 and A>1 and not([A](A-(A>1),B)))+(Ans=34 and A<8 and not([A](A+(A<8),B→A
:B-(K=24 and B>1 and not([A](A,B-(B>1))))+(K=26 and B<16 and not([A](A,B+(B<16→B
:Output(A,Ans,"X
:End

Sorry… :(

Re: Maze Questions

burr 28 Jan 2008 05:57

I understand now. The reason that the numbers don't disappear and reappear is because the random wall movement code isn't inside the Repeat loop:

:4→A:8→B
:[[matrix]]→[A]
:For(Y,1,8
:For(X,1,16
:If Ans(Y,X
:Output(Y,X,1
:End:End
:Repeat 30=abs(K-75
:getKey→K
:If max(Ans={24,25,26,34
:Output(A,B,"  
:A-(Ans=25 and A>1 and not([A](A-(A>1),B)))+(Ans=34 and A<8 and not([A](A+(A<8),B→A
:B-(K=24 and B>1 and not([A](A,B-(B>1))))+(K=26 and B<16 and not([A](A,B+(B<16→B
:Output(A,Ans,"X
:randInt(1,8→Y
:randInt(1,16→X
:If [A](Y,X:Then
:randInt(1,8→S
:randInt(1,16→T
:If not([A](S,T:Then
:Output(S,T,"S
:1→[A](S,T
:Output(Y,X," (1 space)
:0→[A](Y,X
:End:End
:End

Last edited on 28 Jan 2008 07:17 by burr Show more

Re: Maze Questions

Acro 28 Jan 2008 16:34

Okay. I edited my code, started the level up. It loaded, I moved one space, then it gave me an INVALID DIM error, highlighting the colon in

:If [A](Y,X:Then

Bout other than that, everything checks out. Thanks.

Re: Maze Questions

burr 28 Jan 2008 17:13

What are the values of Y and X when that happens? Are they within the appropriate range?

Re: Maze Questions

Acro 28 Jan 2008 17:34

They're 16 by 8, respectively.

Re: Maze Questions

burr 28 Jan 2008 17:50

There's your problem right there. A matrix is accessed {row,column}, which means you probably have your variables backwards.

Re: Maze Questions

Acro 28 Jan 2008 18:44

No, no, you asked what my Y and X values-
Oooh. I meant 8 by 16, i read your Y and X as X and Y.

Re: Maze Questions

burr 28 Jan 2008 18:52

Are you using a matrix with dimensions 8 by 16?

When If [A](Y,X:Then gives you the invalid dim error, choose the Quit option in the error menu. On the home screen, type the variable Y and press ENTER. What value does it give you? Now type the variable X and press ENTER. What value does that give you?

Re: Maze Questions

Acro 28 Jan 2008 21:09

Y gave me a 2 and X gave me 18. I take it that's bad.

Re: Maze Questions

burr 28 Jan 2008 21:28

Yeah, you shouldn't be able to get a value of 18 for X. If you look at these two lines in the movement program code I posted

:randInt(1,8→Y
:randInt(1,16→X

are they the same in your program? I bet you probably have randInt(1,18→X

Re: Maze Questions

Acro 29 Jan 2008 00:43

i fixed that part and it works!