small game optimization

Forum Attachments

Summary:

need guidance on optimizing my quaint little game

small game optimization

Kufii 16 Nov 2010 03:17

So I just made my first "real" TI-Basic game. You play as a small line who falls. At the beginning of each round 50 dots are drawn on screen. Your goal is to reach the bottom without hitting any dots. I've been optimizing whatever I could for about 20 minutes. Anything I missed?

:AxesOff
:FnOff
:0→Xmin:94→Xmax
:0→Ymin:62→Ymax
:0→D
:-125→S
:47→A:4→B
:ClrDraw
:Pt-On(49,61,2
:Pt-On(45,61,2

:While D=0
:Pxl-Off(B,A
:Pxl-Off(B-1,A
:Pxl-Off(B-2,A
:47→A:4→B
:S+125→S

:For(G,0,50
:randInt(0,94)→X
:randInt(8,61)→Y
:Pxl-On(Y,X
:End

:Repeat B=62 or D≠0
:For(G,0,5
:End
:Pxl-Off(B,A
:Pxl-Off(B-1,A
:Pxl-Off(B-2,A
:B+1→B
:A+sum(ΔList(K={24,26}))
:Ans-1(A=94)+1(A=0)→A
:1(pxl-Test(B,A))+1(pxl-Test(B-1,A))+1(pxl-Test(B-2,A))→D
:Pxl-On(B,A
:Pxl-On(B-1,A
:Pxl-On(B-2,A
:getKey→K
:End
:End

:Text(1,1,"DEATH!
:Text(57,1,S
:Text(50,1,"Score:
:Pause
:ClrDraw
:Stop

Re: small game optimization

Xeda Elnara 16 Nov 2010 03:32

These are just simple optimizations…

Instead of

0→D

do

Delvar D

Instead of

While D=0

do

While not(D

Instead of

:randInt(0,94)→X
:randInt(8,61)→Y

do

:randInt(0,94→X
:randInt(8,61→Y

Instead of

:Repeat B=62 or D≠0

do

:Repeat B=62 or D

Instead of

A+sum(ΔList(K={24,26}))

do

A+sum(ΔList(K={24,26

Instead of

:Ans-1(A=94)+1(A=0)→A

do

:Ans-(A=94)+not(A→A

Instead of

:1(pxl-Test(B,A))+1(pxl-Test(B-1,A))+1(pxl-Test(B-2,A))→D

do

:pxl-Test(B,A)+pxl-Test(B-1,A)+pxl-Test(B-2,A→D

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: small game optimization

Kufii 16 Nov 2010 03:40

Will do! Thanks

Re: small game optimization

burr 17 Nov 2010 15:37

I noticed a couple more optimizations you can make:

:For(G,0,50
:randInt(0,94)→X
:randInt(8,61)→Y
:Pxl-On(Y,X
:End
can be
:For(G,0,50
:Pxl-On(randInt(8,61),randInt(0,94
:End

:For(G,0,5
:End
can be
:rand(5

You can also get rid of the Stop command since it is at the end of the program.

Re: small game optimization

BlakPilar 17 Nov 2010 22:12

Aha! I feel special! I found another optimization! Change

:Text(57,1,S
:Text(50,1,"Score:

to

:Text(50,1,"Score: ",S

---

Projects: BexIDE (hold), Hadean.NET, Legend of Zelda: Link to the Future

Re: small game optimization

Kufii 18 Nov 2010 05:08

I can't believe i missed the :Stop… It's so obvious

As for the rand(5, that severely slows down movement

Last edited on 18 Nov 2010 05:12 by Kufii Show more

Re: small game optimization

rhombus p 20 Nov 2010 04:08

change it to just rand then

change

:randInt(0,94)→X
:randInt(8,61)→Y
:Pxl-On(Y,X

to

:Pxl-On(randInt(0,94),randInt(8,61)

slight speed improvment change

:Pxl-On(B,A
:Pxl-On(B-1,A
:Pxl-On(B-2,A

to

:B
:Pxl-On(Ans,A
:Pxl-On(Ans-1,A
:Pxl-On(Ans-2,A

same with the pxl-off's

:B
:Pxl-Off(Ans,A
:Pxl-Off(Ans-1,A
:Pxl-Off(Ans-2,A

---