ERROR: UNDEFINED

Forum Attachments

Summary:

Points to menu, all labels used...

ERROR: UNDEFINED

prgmTrouble 04 Nov 2016 02:14

I have been receiving an error when running the program below at the first menu. I checked all the labels and variables and I cannot figure out what is throwing the error.

Using TI-84 + CSE OS 4.2 and Doors 8.

Main program:

StoreGDB 0
Goto Z
Lbl Y
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)
Lbl Z
{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
Goto Y
Lbl A:RecallGDB 1
Lbl B:RecallGDB 2
Lbl C:RecallGDB 3
Lbl D:RecallGDB 4
Lbl E:RecallGDB 5
Lbl 0
BackgroundOff
AxesOff
GridOff
FnOff 
ClrDraw
132→A
83→B
10→P
Repeat K=45
Repeat K
Pxl-Off(B,A
getKey→K
Pxl-On(B,A,P
End
If K=24 and A>0
A-1→A
If K=26 and A<264
A+1→A
If K=25 and B>0
B-1→B
If K=34 and B<164
B+1→B
If K=105
P+1→P
If P=25
10→P
End
Menu("SAVE?","Y",1,"N",2
Lbl 1
Input "Name",Str6
sub(Str6+"         ",1,10→Str6
Input "Slot Number",S
If S=1
Then
Str6→Str1
1→⌊NAME(1
StoreGDB 1
End
If S=2
Then
Str6→Str2
2→⌊NAME(2
StoreGDB 2
End
If S=3
Then
Str6→Str3
3→⌊NAME(3
StoreGDB 3
End
If S=4
Then
Str6→Str4
4→⌊NAME(4
StoreGDB 4
End
If S=5
Then
Str6→Str5
5→⌊NAME(5
StoreGDB 5
End
Lbl 2
If Q+R+S+T+U=0
Then
"[...]"→Str1:Ans→Str2:Ans→Str3:Ans→Str4:Ans→Str5
End

ClrHome
Asm(prgmTOGLARCH
UnArchive prgmCLEANUP
Asm(prgmTOGLARCH
prgmCLEANUP
Asm(prgmTOGLARCH
Archive prgmCLEANUP
Asm(prgmTOGLARCH

prgmTOGLARCH

Asm84CPrgm
FD7E08EE02FD7708C9

prgmCLEANUP

Menu("SETTINGS","Radian",1,"Degree",2)
Lbl 1
Radian
Goto A
Lbl 2
Degree
Goto A
Lbl A
DelVar Y₁DelVar Y₂DelVar Y₃DelVar Y₄DelVar Y₅DelVar Y₆DelVar Y₇DelVar Y₈DelVar Y₉DelVar Y₀
ClrDraw
ClrAllLists
Normal
Float
Func
Thin
Simul
a+b
Full
nd
DEC
RectGC
GridLine 
AxesOn 
ZStandard
ZSquare
RecallGDB 0
Return

Thanks in advance!

Last edited on 04 Nov 2016 02:23 by prgmTrouble Show more

Re: ERROR: UNDEFINED

jonbush 04 Nov 2016 03:01

I believe the problem is that one or more of the String variables used in your Menu( has not been initialized. You cannot use an empty string, so this would create the Error: Undefined.

---

Additionally, part of your code can be restructured to reduce the number of Gotos required:

Goto Z
Lbl Y
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)
Lbl Z
{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
Goto Y

can be

{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)

---

You might also want to note that the code below will always result in GDB5 being recalled because the code after each previous label will also run:

Lbl A:RecallGDB 1
Lbl B:RecallGDB 2
Lbl C:RecallGDB 3
Lbl D:RecallGDB 4
Lbl E:RecallGDB 5

If this is not the intended behavior, you could do this:

1
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)
Lbl E:Ans+1
Lbl D:Ans+1
Lbl C:Ans+1
Lbl B:Ans+1
Lbl A
RecallGDB Ans
Lbl 0

Re: ERROR: UNDEFINED

prgmTrouble 04 Nov 2016 04:44

Thanks alot for the input!
I got the initial error solved (it was the strings after all) and I am now working on some minor improvements. I might be back with yet more issues.

Re: ERROR: UNDEFINED

prgmTrouble 04 Nov 2016 05:16

As I said, I am back with yet another issue:
ERROR: SYNTAX

StoreGDB 0
If M=0
Then
For(M,0,0.1)
"[...]"→Str1:Ans→Str2:Ans→Str3:Ans→Str4:Ans→Str5
End
End
{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
1→Z
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)
Lbl E:Z+1
Lbl D:Z+1
Lbl C:Z+1
Lbl B:Z+1
Lbl A
If Q=0 and Z=1 [occurs here!]
Then:Goto 0
End
If R=0 and Z=2
Then:Goto 0
End
If S=0 and Z=3 
Then:Goto 0
End
If T=0 and Z=4
Then:Goto 0
End
If U=0 and Z=5
Then:Goto 0
End
RecallGDB Z
Goto 3
End
Lbl 0
BackgroundOff
AxesOff
GridOff
FnOff 
ClrDraw
Lbl 3
132→A
83→B
10→P
Repeat K=45
Repeat K
Pxl-Off(B,A
getKey→K
Pxl-On(B,A,P
End
If K=24 and A>0
A-1→A
If K=26 and A<264
A+1→A
If K=25 and B>0
B-1→B
If K=34 and B<164
B+1→B
If K=105
P+1→P
If P=25
10→P
End
Menu("SAVE?","Y",1,"N",2
Lbl 1
Input "Name",Str6
Input "Slot Number",M

sub(Str6+"         ",1,10→Str6
If M=1
Then
Str6→Str1
1→⌊NAME(1
StoreGDB 1
End
If M=2
Then
Str6→Str2
2→⌊NAME(2
StoreGDB 2
End
If M=3
Then
Str6→Str3
3→⌊NAME(3
StoreGDB 3
End
If M=4
Then
Str6→Str4
4→⌊NAME(4
StoreGDB 4
End
If M=5
Then
Str6→Str5
5→⌊NAME(5
StoreGDB 5
End

Lbl 2

ClrHome
Asm(prgmTOGLARCH
UnArchive prgmCLEANUP
Asm(prgmTOGLARCH
prgmCLEANUP
Asm(prgmTOGLARCH
Archive prgmCLEANUP
Asm(prgmTOGLARCH

The goal is to not recall the GDB upon selecting an invalid item and instead perform the same action as the "New" selection would.

Last edited on 04 Nov 2016 05:20 by prgmTrouble Show more

Re: ERROR: UNDEFINED

jonbush 04 Nov 2016 15:42

It is generally considered a bad practice to jump out of any structure that requires an End with a Goto, because this creates a memory leak which can lead to more errors. I'm not exactly sure why a syntax error would occur at that line as it looks fine; you might check if there is an extra space or something.

This code:

If Q=0 and Z=1 [occurs here!]
Then:Goto 0
End
If R=0 and Z=2
Then:Goto 0
End
If S=0 and Z=3 
Then:Goto 0
End
If T=0 and Z=4
Then:Goto 0
End
If U=0 and Z=5
Then:Goto 0
End

can be condensed to

If max((Z={1,2,3,4,5})not({Q,R,S,T,U
Goto 0

Remember that you don't need Then and End if there is only a single line after the If statement.

Re: ERROR: UNDEFINED

prgmTrouble 04 Nov 2016 22:20

I am now getting an
ERROR: UNDEFINED

StoreGDB 0
If M=0
Then
For(M,0,0.1)
"[...]"→Str1:Ans→Str2:Ans→Str3:Ans→Str4:Ans→Str5
End
End
{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
1→Z
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)
Lbl E:Z+1
Lbl D:Z+1
Lbl C:Z+1
Lbl B:Z+1
Lbl A
If max((Z={1,2,3,4,5})not({Q,R,S,T,U
Goto 0
RecallGDB Z  [Here!]
Goto 3
Lbl 0
BackgroundOff
AxesOff
GridOff
FnOff 
ClrDraw
Lbl 3
132→A
83→B
10→P
Repeat K=45
Repeat K
Pxl-Off(B,A
getKey→K
Pxl-On(B,A,P
End
If K=24 and A>0
A-1→A
If K=26 and A<264
A+1→A
If K=25 and B>0
B-1→B
If K=34 and B<164
B+1→B
If K=105
P+1→P
If P=25
10→P
End
Menu("SAVE?","Y",1,"N",2
Lbl 1
Input "Name",Str6
Input "Slot Number",M

sub(Str6+"         ",1,10→Str6
If M=1
Then
Str6→Str1
1→⌊NAME(1
StoreGDB 1
End
If M=2
Then
Str6→Str2
2→⌊NAME(2
StoreGDB 2
End
If M=3
Then
Str6→Str3
3→⌊NAME(3
StoreGDB 3
End
If M=4
Then
Str6→Str4
4→⌊NAME(4
StoreGDB 4
End
If M=5
Then
Str6→Str5
5→⌊NAME(5
StoreGDB 5
End

Lbl 2

ClrHome
Asm(prgmTOGLARCH
UnArchive prgmCLEANUP
Asm(prgmTOGLARCH
prgmCLEANUP
Asm(prgmTOGLARCH
Archive prgmCLEANUP
Asm(prgmTOGLARCH

upon selecting a menu item other than "New"
The error should be avoided by the goto, yet it still persists for some reason.

Re: ERROR: UNDEFINED

jonbush 05 Nov 2016 00:59

I guess I was incorrect about the RecallGDB command. Apparently RecallGDB doesn't accept variables for arguments, so you will have to find a different (albeit less elegant) solution to this problem

Re: ERROR: UNDEFINED

prgmTrouble 05 Nov 2016 04:35

Thanks, I'll probably try an expr(

Re: ERROR: UNDEFINED

prgmTrouble 05 Nov 2016 05:34

I ended up fixing the problem:

StoreGDB 0
If M=0
Then
For(M,0,0.1)
"[...]"→Str1:Ans→Str2:Ans→Str3:Ans→Str4:Ans→Str5
End
End
{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
1→Z
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫","New",0,Str1,A,Str2,B,Str3,C,Str4,D,Str5,E)
If max((Z={1,2,3,4,5})not({Q,R,S,T,U
Goto 0
End
Lbl A
RecallGDB GDB1
Goto 3
Lbl B:Z+1
RecallGDB GDB2
Goto 3
Lbl C:Z+2
RecallGDB GDB3
Goto 3 
Lbl D:Z+3
RecallGDB GDB4
Goto 3 
Lbl E:Z+4
RecallGDB GDB5
Goto 3 

Lbl 0
BackgroundOff
AxesOff
GridOff
FnOff 
ClrDraw
Lbl 3
132→A
83→B
10→P
Repeat K=45
Repeat K
Pxl-Off(B,A
getKey→K
Pxl-On(B,A,P
End
If K=24 and A>0
A-1→A
If K=26 and A<264
A+1→A
If K=25 and B>0
B-1→B
If K=34 and B<164
B+1→B
If K=105
P+1→P
If P=25
10→P
End
Menu("SAVE?","Y",1,"N",2
Lbl 1
Input "Name",Str6
Input "Slot Number",M

sub(Str6+"         ",1,10→Str6
If M=1
Then
Str6→Str1
1→⌊NAME(1
StoreGDB GDB1
End
If M=2
Then
Str6→Str2
2→⌊NAME(2
StoreGDB GDB2
End
If M=3
Then
Str6→Str3
3→⌊NAME(3
StoreGDB GDB3
End
If M=4
Then
Str6→Str4
4→⌊NAME(4
StoreGDB GDB4
End
If M=5
Then
Str6→Str5
5→⌊NAME(5
StoreGDB GDB5
End

Lbl 2

ClrHome
Asm(prgmTOGLARCH
UnArchive prgmCLEANUP
Asm(prgmTOGLARCH
prgmCLEANUP
Asm(prgmTOGLARCH
Archive prgmCLEANUP
Asm(prgmTOGLARCH

However, the GDB does not appear after the slot is selected. I cannot figure out if the problem is the store or recall functions.

Re: ERROR: UNDEFINED

jonbush 05 Nov 2016 19:32

I'm not exactly certain what you mean by "the GDB does not appear." Perhaps you are looking for the DispGraph command?

Re: ERROR: UNDEFINED

prgmTrouble 05 Nov 2016 19:51

So I would do a recallgdb and then a dispgraph?

Re: ERROR: UNDEFINED

jonbush 05 Nov 2016 21:39

That is what you would do if you want it to display the graph screen after recalling the GDB.

Re: ERROR: UNDEFINED

prgmTrouble 06 Nov 2016 03:03

I managed to finish the program without seeing any errors in my tests!
Thanks again for the help!

Main:

StoreGDB 0

If M=0
Then
For(M,0,0.1)
"[...]"→Str1:Ans→Str2:Ans→Str3:Ans→Str4:Ans→Str5
ClrDraw
StorePic 1
StorePic 2
StorePic 3
StorePic 4
StorePic 5
End
End

SetUpEditor L₁
0→X
If 10≠dim(L₁:Then:1→X:0→Q
{37,37,37,37,37,37,37,37,37,37,37}→L₁
End
"?
For(θ,1,dim(L₁
Ans+sub("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ [.]",L₁(θ)-1+X,1
End
sub(Ans,2,length(Ans)-1→Str1

SetUpEditor L₂
0→X
If 10≠dim(L₂:Then:1→X:0→R
{37,37,37,37,37,37,37,37,37,37,37}→L₂
End
"?
For(θ,1,dim(L₂
Ans+sub("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ [.]",L₂(θ)-1+X,1
End
sub(Ans,2,length(Ans)-1→Str2

SetUpEditor L₃
0→X
If 10≠dim(L₃:Then:1→X:0→S
{37,37,37,37,37,37,37,37,37,37,37}→L₃
End
"?
For(θ,1,dim(L₃
Ans+sub("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ [.]",L₃(θ)-1+X,1
End
sub(Ans,2,length(Ans)-1→Str3

SetUpEditor L₄
0→X
If 10≠dim(L₄:Then:1→X:0→T
{37,37,37,37,37,37,37,37,37,37,37}→L₄
End
"?
For(θ,1,dim(L₄
Ans+sub("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ [.]",L₄(θ)-1+X,1
End
sub(Ans,2,length(Ans)-1→Str4

SetUpEditor L₅
0→X
If 10≠dim(L₅:Then:1→X:0→U
{37,37,37,37,37,37,37,37,37,37,37}→L₅
End
"?
For(θ,1,dim(L₅
Ans+sub("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ [.]",L₅(θ)-1+X,1
End
sub(Ans,2,length(Ans)-1→Str5

{Q,R,S,T,U→NAME
Archive ⌊NAME
SetUpEditor NAME
If not(dim(⌊NAME
{0,0,0,0,0→NAME
⌊NAME(1→Q:⌊NAME(2→R:⌊NAME(3→S:⌊NAME(4→T:⌊NAME(5→U
1→Z
Menu("▫▫▫▫▫▫▫▫▫▫▫Open▫▫▫▫▫▫▫▫▫▫▫",Str1,A,Str2,B,Str3,C,Str4,D,Str5,E,"New",0)
ClrDraw
Lbl A
If Q=0
Goto 0
RecallPic 1
DispGraph
Goto 0

Lbl B:Z+1
If R=0
Goto 0
RecallPic 2
DispGraph
Goto 0

Lbl C:Z+2
If S=0
Goto 0
RecallPic 3
DispGraph
Goto 0 

Lbl D:Z+3
If T=0
Goto 0
RecallPic 4
DispGraph
Goto 0 

Lbl E:Z+4
If U=0
Goto 0
RecallPic 5
DispGraph
Goto 0 

Lbl 0

132→A
83→B
10→P
Repeat K=45
Repeat K
Pxl-Off(B,A
getKey→K
Pxl-On(B,A,P
TextColor(P)
Text(0,107,"[COLOR]")
End
If K=24 and A>0
A-1→A
If K=26 and A<264
A+1→A
If K=25 and B>0
B-1→B
If K=34 and B<164
B+1→B
If K=105
P+1→P
If P=25
10→P
End
Menu("SAVE?","Y",1,"N",2
Lbl 1
Input "Name: ",Str6
Input "Slot Number: ",M

sub(Str6+"         ",1,10→Str6
If M=1
Then
1+seq(inString("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ ",sub(Str6,θ,1)),θ,1,length(Str6→L₁
1→⌊NAME(1
StorePic 1
0→X
10→dim(L₁
End
If M=2
Then
1+seq(inString("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ ",sub(Str6,θ,1)),θ,1,length(Str6→L₂
2→⌊NAME(2
StorePic 2
0→X
10→dim(L₂
End
If M=3
Then
1+seq(inString("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ ",sub(Str6,θ,1)),θ,1,length(Str6→L₃
3→⌊NAME(3
StorePic 3
0→X
10→dim(L₃
End
If M=4
Then
1+seq(inString("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ ",sub(Str6,θ,1)),θ,1,length(Str6→L₄
4→⌊NAME(4
StorePic 4
0→X
10→dim(L₄
End
If M=5
Then
1+seq(inString("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ ",sub(Str6,θ,1)),θ,1,length(Str6→L₅
5→⌊NAME(5
StorePic 5
0→X
10→dim(L₅
End
Archive L₁:Archive L₂:Archive L₃:Archive L₄:Archive L₅
Lbl 2
SetUpEditor 
ClrDraw
ClrHome
Asm(prgmTOGLARCH
UnArchive prgmCLEANUP
Asm(prgmTOGLARCH
prgmCLEANUP
Asm(prgmTOGLARCH
Archive prgmCLEANUP
Asm(prgmTOGLARCH

prgmTOGLARCH

Asm84CPrgm
FD7E08EE02FD7708C9

prgmCLEANUP

Menu("SETTINGS","Radian",1,"Degree",2)
Lbl 1
Radian
Goto A
Lbl 2
Degree
Goto A
Lbl A
DelVar Y₁DelVar Y₂DelVar Y₃DelVar Y₄DelVar Y₅DelVar Y₆DelVar Y₇DelVar Y₈DelVar Y₉DelVar Y₀

Normal
Float
Func
Thin
Simul
a+b
Full
nd
DEC
RectGC
GridLine 
AxesOn 
ZStandard
ZSquare
FnOn 
Return

Last edited on 06 Nov 2016 05:53 by prgmTrouble Show more