inFINITE Beta / Discussion

Forum Attachments

This is the discussion related to the wiki page inFINITE Beta.

source code please

m3m3b01 13 Feb 2020 15:32

can someone give me the source code i cant use sourcecoder3 it would be really helpful.

Re: source code please

FoxxTrott 23 Feb 2021 14:59

There are 7 different programs.

PRGM: CONTRAST
:AsmPrgmEFD74AEFEF4AC6D8D8D3107B324784C9

PRGM: ASMS1
:AsmPrgm213F960E40060CB7CB162B10FB0D20F5EF6A48C9

PRGM: ASMR1
:AsmPrgm2140930E40060CB7CB1E2310FB0D20F5EF6A48C9

PRGM: NBRD
:Vertical Xmin
:Vertical Xmax
:Horizontal Ymin
:Horizontal Ymax

PRGM: NSETUP
:1->Q
:SetUpEditor |LNDTA
:If not(dim(|LNDTA
:5->dim(|LNDTA
:SetUpEditor |LNSHP
:If not(dim(|LNSHP
:{50,300,200,250,0,0,0->|LNSHP
:SetUpEditor |LNP
:If not(dim(|LNP
:{0,0,5,0,50,1,0,0,50,30,0->|LNP
:SetUpEditor NSC
:If not(dim(|LNSC
:22->dim(|LNSC
:SetUpEditor |LNE
:If not(dim(|LNE
:{10,10,4,10->|LNE
:SetUpEditor |LNCLS
:If not(dim(|LNCLS
:{1->|LNCLS

PRGM: ASMU1
:AsmPrgm214C9311409301F402EDB0EB010C00EF304CEF6A48C9

PRGM: INFINITE
:29->P
:Asm(prgmCONTRAST
:Goto 1
:Lbl BG
:ClrDraw
:For(A,0,30,2
:    A
:    Asm(prgmCONTRAST
:End
:Lbl 1
:ClrDraw
:AxesOff:FnOff 
:ClrHome
:0->Xmin:94->Xmax
:0->Ymin:62->Ymax
:Text(28,33,"INFINITE
:
:Line(46,18,46,13
:Line(48,11,48,20
:Pt-On(47,12
:Pt-On(46,35
:Pt-On(48,35
:Line(50,36,44,36
:Line(45,37,49,37
:Line(47,40,47,38
:
:Line(44,19,41,19
:Line(45,20,40,20
:Line(40,21,40,26
:Line(39,25,39,21
:Line(41,27,45,27
:Line(46,26,40,26
:Pt-On(45,25
:Pt-On(41,25
:Pt-On(41,21
:Pt-On(45,21
:Line(46,26,46,23
:Line(47,21,47,25
:Line(48,23,48,20
:Line(49,21,49,19
:Line(50,20,54,20
:Line(53,19,49,19
:Pt-On(53,21
:Line(54,20,54,26
:Line(55,25,55,21
:Pt-On(53,25
:Line(54,26,49,26
:Line(50,27,53,27
:Pt-On(49,25
:Text(57,0,"(
:For(A,2,94
:    Text(57,A,")
:End
:For(A,0,94,5
:    Text(~1,55,A," 
:End
:For(A,29,1,~5
:    A
:    Asm(prgmCONTRAST
:End
:Lbl MK
:For(A,1,21
:    Asm(prgmASMU1
:End
:SetUpEditor |LNP
:If not(dim(|LNP:Then
:    Text(29,33,"NEW GAME
:Else
:    Text(29,32,"CONTINUE
:End
:Text(35,38,"STATS
:Text(41,26,"ACHEIVMENTS
:Text(47,32,"PASSCODE
:Text(53,40,"QUIT
:StorePic 4
:For(A,0,30,5
:    A
:    Asm(prgmCONTRAST
:End
:Lbl ML
:ClrDraw
:RecallPic 4
:Lbl 3
:Repeat K=21
:    getKey->K
:    If Ans:Then
:        Text(P,2,"   
:        Text(P,90,"   
:    End
:    P+6(K=34)(P<53)-6(K=25)(P>29->P
:    Text(P,2,">
:    Text(P,90,"<
:End
:If P=53:Goto Q
:If P=29:Goto CL
:If P=35:Goto HS
:If P=41:Goto AC
:If P=47:Then
:    SetUpEditor |LNP
:    If not(dim(|LNP)):Then
:        Lbl HS
:        For(X,1,3
:            Asm(prgmASMS1
:            Asm(prgmASMR1
:        End
:        Goto 3
:    Else
:        If |LNP(11)=1:Then
:            For(X,1,3
:                Asm(prgmASMS1
:                Asm(prgmASMR1
:            End
:            Goto 3
:        Else
:            Goto PC
:        End
:    End
:End
:Lbl Q
:ClrDraw
:ZStandard
:AxesOn:FnOn 
:Disp 
:Stop
:Lbl PC
:ClrHome
:SetUpEditor |LNP
:0->A
:Repeat A>3
:    Input "PASS:",Str5
:    If Str5="README":Then
:        Disp "YAY!"
:        |LNP(4)+2000->|LNP(4
:        |LNP(10)+100->|LNP(10
:        1->|LNP(11
:        Pause 
:        Output(4,1,"2000 G and 100 D have been addedto your game
:        Pause 
:        ClrHome
:        Goto ML
:    Else
:        A+1->A
:        Disp "NAY! >:(
:    End
:End
:Goto ML
:Lbl AC
:SetUpEditor |LNSC
:If not(dim(|LNSC
:22->dim(|LNSC
:UnArchive |LNSC
:ClrDraw
:Horizontal 54
:Vertical 52
:prgmNBRD
:Text(1,2,"Acheivments
:SetUpEditor |LNDTA,|LNSC
:5->dim(|LNDTA
:22->dim(|LNSC
:0->C
:For(A,25,100,25
:    C+1->C
:    If |LNDTA(1)>=A
:    1->|LNSC(C
:    If |LNDTA(2)>=A/2.5
:    1->|LNSC(C+4
:    If |LNDTA(3)>=240A
:    1->|LNSC(C+8
:    If |LNDTA(4)>=A/5
:    1->|LNSC(C+12
:    If |LNDTA(5)>=40A
:    1->|LNSC(C+16
:End
:3->X:~2->Y
:For(theta,1,4
:    Y+3->Y
:    X+6->X
:    Text(X,2,"Slayer",sub("I  II IIIIV ",Y,3
:End
:~2->Y
:For(theta,1,4
:    X+6->X
:    Y+3->Y
:    Text(X,2,"Challenger",sub("I  II IIIIV ",Y,3
:End
:3->X
:For(theta,1,8
:    X+6->X
:    theta->Y
:    Text(X,54,sub("INCOMPLETECOMPLETE  ",1+10(|LNSC(Y)=1),10
:End
:Pause 
:ClrDraw
:Horizontal 54
:prgmNBRD
:Vertical 52
:Text(1,2,"Acheivments
:3->X:~2->Y
:For(theta,1,5
:    X+6->X
:    Y+3->Y
:    Text(X,2,"Wealth ",sub("I  II IIIIV V  ",Y,3
:End
:~2->Y
:For(theta,1,3
:    X+6->X
:    Y+3->Y
:    Text(X,2,"K.O.",sub("I  II III",Y,3
:End
:3->X:9->Y
:For(theta,1,8
:    X+6->X
:    Y+1->Y
:    Text(X,54,sub("INCOMPLETECOMPLETE  ",1+10(|LNSC(Y)=1),10
:End
:Pause 
:ClrDraw
:Horizontal 54
:Vertical 52
:prgmNBRD
:Text(1,2,"Acheivments
:3->X:~2->Y
:For(theta,1,5
:    X+6->X
:    Y+3->Y
:    Text(X,2,"XP  ",sub("I  II IIIIV V  ",Y,3
:End
:3->X:17->Y
:For(theta,1,5
:    Y+1->Y
:    X+6->X
:    Text(X,54,sub("INCOMPLETECOMPLETE  ",1+10(|LNSC(Y)=1),10
:End
:Pause 
:Archive |LNSC
:Goto ML
:Lbl CL
:SetUpEditor |LNCLS
:If not(dim(|LNCLS:Then
:    Goto NP
:Else
:    Goto AP
:End
:Lbl NP
:ClrHome
:prgmNSETUP
:ClrDraw
:prgmNBRD
:Text(2,2,"WORLD/CLASS SELECT
:Text(17,2,"Grasslands
:Text(23,2,"Forest
:Text(29,2,"Ruins
:Text(35,2,"Magma
:Text(41,2,"Depths
:Horizontal 52
:For(A,49,69,5
:    Text(13,A,sub("AKNBW",(A-44)/5,1
:End
:17->A
:Repeat K=21
:    getKey->K
:    If Ans
:    Text(A,38,"   
:    A+6(K=34)(A<41)-6(K=25)(A>17->A
:    Text(A,38,"<
:End
:~3->C
:For(B,17,41,6
:    C+4->C
:    If A=B:Then
:        C->|LNCLS(1
:        C+10->|LNE(1
:        Ans->|LNE(2
:End:End
:49->A
:Text(32,42,"Gold
:Text(38,42,"Diamonds
:Text(44,42,"HP
:Text(50,42,"Attack
:Repeat K=21
:    getKey->K
:    If Ans
:    Text(19,A,"   
:    If A=49:Then
:        2000->B:200->C:30->D:5->E
:    End
:    If A=54:Then
:        1500->B:150->C:50->D:7->E
:    End
:    If A=59:Then
:        1000->B:100->C:45->D:9->E
:    End
:    If A=64:Then
:        300->B:10->C:90->D:15->E
:    End
:    If A=69:Then
:        1500->B:50->C:55->D:10->E
:    End
:    A+5(K=26)(A<69)-5(K=24)(A>49->A
:    Text(19,A,"^
:    Text(32,75,B,"   
:    Text(38,75,C,"   
:    Text(44,75,D,"   
:    Text(50,75,E,"   
:End
:B->|LNP(4
:C->|LNP(10
:D->|LNP(1
:Ans->|LNP(2
:E->|LNP(3
:sub("AKNBW",(A-44)/5,1->Str4
:Lbl AP
:UnArchive |LNCLS
:UnArchive |LNDTA
:UnArchive |LNE
:UnArchive |LNP
:UnArchive |LNSC
:UnArchive |LNSHP
:ClrDraw
:Line(2,20,92,20
:Line(1,19,1,17
:Line(93,17,93,19
:Line(2,16,92,16
:Line(22,15,22,0
:Horizontal 0
:Text(47,2,"STAGE
:Text(48,24,"G:
:Text(54,24,"D:
:Text(48,42-4(|LNP(4)>=10)-4(|LNP(4)>=100)-4(|LNP(4)>=1000),|LNP(4
:Text(54,42-4(|LNP(10)>=10)-4(|LNP(10)>=100),|LNP(10
:Text(51,85-4(|LNP(7)>=10)-4(|LNP(7)>=100)-4(|LNP(7)>=1000),|LNP(7
:Text(48,58-4(|LNP(5)>=10),|LNP(5
:Text(~1,54,13-6(|LNP(8)>=10),|LNP(8
:For(X,46,52
:    Text(54,X,sub("xo:[xbar]Y  ",X-45,1
:End
:Line(7,29,7,53
:Line(2,49,1,48
:Text(0,11-4(|LNP(1)>=10)-4(|LNP(1)>=100),|LNP(1
:Text(0,15,"/
:Text(0,27-4(|LNP(2)>=10)-4(|LNP(2)>=100),|LNP(2
:Text(0,74-4(|LNE(1)>=10)-4(|LNE(1)>=100),|LNE(1
:Text(0,78,"/
:"4int(log(Ans+not(Ans->|u
:|LNP(4
:Text(48,42-|u,Ans
:|LNP(10
:Text(54,42-|u,Ans
:|LNP(7
:Text(51,85-|u,Ans
:Text(48,58-|u,Ans
:Text(~1,54,13-6(|LNP(8)>=10),|LNP(8
:For(X,46,52
:    Text(54,X,sub("xo:[xbar]Y  ",X-45,1
:End
:0->W
:For(Z,9,27,6
:    For(theta,1,7
:        Text(Z,theta,sub("xo:[xbar]Y  ([i2(  {y!y{  +:I:+  ",W+theta,1
:    End
:    W+7->W
:End
:Line(7,29,7,53
:Line(2,49,1,48
:|LNP(1
:Text(0,11-|u,Ans
:Text(0,15,"/
:|LNP(2
:Text(0,27-|u,Ans
:|LNE(1
:Text(0,74-|u,Ans
:Text(0,78,"/
:|LNE(2
:Text(0,90-|u,Ans
:Text(48,52,":
:Text(54,52,":
:Text(51,63,"XP:
:For(C,3,92,2
:    Pt-On(C,19
:    Pt-On(C-1,18
:End
:Disp 
:rand(2
:DispGraph
:Lbl WI
:Text(36,26,Str4
:randInt(|LNCLS(1),|LNCLS(1)+3
:sub("x[xbar]y[ybar]FgHdVWSQmklLXYZtheta",Ans,1->Str1
:9->A
:Lbl TR
:Text(36,76,Str1
:Repeat K=21
:    getKey->K
:    If Ans
:    Text(A,9,"   
:    If K=45:Then
:        Archive |LNCLS
:        Archive |LNDTA
:        Archive |LNE
:        Archive |LNP
:        Archive |LNSC
:        Archive |LNSHP
:        Goto Q
:    End
:    If K=22:Goto ML
:    A+6(K=34)-6(K=25->A
:    If A>27:9->A
:    If A<9:27->A
:    Text(A,9,"<
:End
:If A=9:Goto AK
:If A=21:Goto IY
:If A=15:Goto HL
:If A=27:Goto DM
:Lbl AK
:randInt(~|LNE(4),|LNE(4),2
:If Ans(1)=Ans(2:Then
:    Text(29,66,"DODGED
:    rand(40
:    Text(~1,29,66,"           
:    Goto ET
:End
:randInt(|LNP(3)-3,|LNP(3->D
:|LNE(1)-D->|LNE(1
:Asm(prgmASMR1
:Asm(prgmASMS1
:Text(0,70,"       
:If |LNE(1)<0
:0->|LNE(1
:|LNE(1
:Text(0,74-|u,Ans
:If |LNE(1)=0:Then
:    For(C,1,2
:        Asm(prgmASMS1
:        Asm(prgmASMR1
:    End
:    |LNP(8)+1->|LNP(8
:    If Ans=20:Then
:        Text(9,22,"WORLD COMPLETE!
:        Pause 
:        Text(16,33,"Continue?
:        Text(24,22,"1) YES
:        Text(24,61,"2) NO
:        Repeat max(K={92,93
:            getKey->K
:        End
:        If K=92:Then
:            For(J,1,29
:                Line(20+J,33,20+J,52,0
:                Line(76-J,33,76-J,52,0
:            End
:        Else
:            0->|LNP(8
:            Goto NP
:        End
:    End
:    Text(11,29,"Enemy Defeated!
:    |LNDTA(1)+1->|LNDTA(1
:    randInt(100,150->Y
:    Y+|LNDTA(3->|LNDTA(3
:    Y+|LNP(4->|LNP(4
:    |LNP(4
:    Text(48,42-|u,Ans
:    randInt(50,100->I
:    I+|LNDTA(5->|LNDTA(5
:    I+|LNP(7->|LNP(7
:    |LNP(7
:    Text(51,85-|u,Ans
:    Text(48,58-4(|LNP(5)>=10),|LNP(5
:    1+|LNP(6->|LNP(6
:    Text(~1,54,13-6(|LNP(8)>=10),|LNP(8
:    1+|LNDTA(2->|LNDTA(1
:    1+|LNE(3->|LNE(3
:    1+|LNE(2->|LNE(2
:    Ans->|LNE(1
:    |LNE(1
:    Text(0,74-|u,Ans
:    |LNE(2
:    Text(0,90-|u,Ans
:    |LNP(6
:    Text(54,58-|u,Ans
:    randInt(10,20->J
:    J+|LNP(10->|LNP(10
:    |LNP(10
:    Text(54,42-|u,Ans
:    Text(17,30,"+",Y," G
:    Text(23,30,"+",I," XP
:    Text(29,30,"+",D," D
:    rand(50
:    For(J,29,85
:        Line(J,51,J,28,0
:    End
:    Goto WI
:Else
:    Goto ET
:End:End
:Lbl HL
:If 0<|LNP(5:Then
:    |LNP(5)-1->|LNP(5
:    |LNP(2->|LNP(1
:    Text(48,58-4(|LNP(5)>=10),|LNP(5
:    |LNP(1
:    Text(0,11-|u,Ans
:End
:Goto ET
:Lbl IY
:ClrDraw
:Text(~1,0,0,"UPGRADES
:Horizontal 54
:Text(55,4,"Cost:
:Text(11,4,"Attack(+2)
:Text(22,4,"Defense(+0.01)
:Text(33,4,"Max HP(+1)
:For(C,44,22,~11
:    Line(4,C,54,C
:    Line(55,C-1,55,C-2
:    Line(4,C-3,54,C-3
:    Line(3,C-1,3,C-2
:End
:Text(49,60,"Gold:
:|LNP(4
:Text(49,89-|u,Ans
:42->B
:For(C,5,7
:    For(A,1,|LNSHP(C
:        Line(A+3,B,A+3,B+1
:    End
:    B-11->B
:End
:41->L
:While 1
:    Repeat K=21
:        getKey->K
:        If Ans:Then
:            Text(~1,48,77,"   
:            Line(0,L,0,L+9,0
:        End
:        If K=45:Goto AP
:        L+11(K=25)(L<41)-11(K=34)(L>19->L
:        Line(0,L,0,L+9
:        Text(55,20,|LNSHP((L+3)/11
:        |LNP(4
:        Text(49,89-|u,Ans
:    End
:    If |LNP(4)>=|LNSHP((L+3)/11:Then
:        |LNP(4)-|LNSHP(int(L/9->|LNP(4
:        If L=41:Then
:            |LNP(3)+2->|LNP(3
:            |LNSHP(5)+1->|LNSHP(5
:            Line(Ans+3,42,Ans+3,43
:        End
:        If L=30:Then
:            Q-.01->Q
:            |LNSHP(6)+1->|LNSHP(6
:            Line(Ans+3,31,Ans+3,32
:        End
:        If L=19:Then
:            |LNP(2)+2->|LNP(2
:            Ans->|LNP(1
:            |LNSHP(7)+1->|LNSHP(7
:            Line(Ans+3,21,Ans+3,20
:        End
:    End
:    |LNP(4
:    Text(49,89-|u,Ans
:End
:Lbl ET
:randInt(~1,1,2
:If Ans(1)=Ans(2:Then
:    Text(29,17,"DODGED
:    rand(40
:    Text(~1,29,17,"       
:    Goto TR
:End
:randInt(|LNE(3)-3,|LNE(3->D
:int(DQ->D
:Asm(prgmASMS1
:Asm(prgmASMR1
:|LNP(1)-D->|LNP(1
:Text(0,3,"            
:|LNP(1
:Text(0,11-|u,Ans
:If |LNP(1)<=0:Then
:    If M=1:Then
:        |LNP(2->|LNP(1
:        0->M
:        |LNP(1
:        Text(0,11-|u,Ans
:        Goto TR
:    Else
:        For(C,1,2
:            Asm(prgmASMS1
:            Asm(prgmASMR1
:        End
:        Text(21,33,"GAME OVER
:        |LNDTA(4)+1->|LNDTA(4
:        Pause 
:        For(C,30,1,~5
:            C
:            Asm(prgmCONTRAST
:        End
:        DelVar |LNP
:        DelVar |LNE
:        DelVar |LNSC
:        DelVar |LNDTA
:        DelVar |LNCLS
:        DelVar |LNSHP
:        ClrDraw
:        Goto BG
:    End
:End
:Goto TR

I do not take credit for any of this code, I give it all to the creator, Battlesquid.