154 Byte Avalanche Game for TI-83/84+

Forum Attachments

Summary:

This is an extremely small game that will only take you a minute or two to type in on your calculator.

154 Byte Avalanche Game for TI-83/84+

J_Walker87 26 Jan 2021 17:08

Hey, I made a redo of an avalanche game that is optimized to take up as little space as possible. It only takes up 154 bytes of RAM on my TI-83+. If you have a minute to spare, you might enjoy typing it in and playing it. The game is fast-paced and goes on forever until you die. You are the streak of "8"s. Avoid hitting the "0"s that fly across the screen by using the arrow keys.

Here's the source code:

DelVar L1
5->dim(L1
For(X,1,7
Disp "
End
Repeat Ans
L1(4->L1(5
L1(3->L1(4
L1(2->L1(3
L1(1->L1(2
randInt(1,16->L1(1
Output(8,Ans,0
Disp "
getKey
X+(Ans=26)-(Ans=24
Ans+16((Ans=0)-(Ans=17->X
Output(3,Ans,8
Ans=L1(5
End

If you see anywhere where I can shave a couple bytes, please let me know. Also, I plan to make a version with a couple more features in the future. If you have any ideas, please let me know and I might implement them.

Last edited on 27 Jan 2021 00:24 by J_Walker87 Show more

Re: 154 Byte Avalanche Game for TI-83/84+

(account deleted) 26 Jan 2021 20:38

You can change

X+(Ans=26)-(Ans=24
Ans+16((Ans=0)-(Ans=17->X

To

max(1,min(16,K+(K=26)-(K=24)->X

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Re: 154 Byte Avalanche Game for TI-83/84+

J_Walker87 26 Jan 2021 22:53

That code doesn't work. The current X doesn't play a factor in determining the future X value in that code snippet. Also, I want it to retain the screen wrapping functionality I gave it.

Re: 154 Byte Avalanche Game for TI-83/84+

CalcNerd 26 Jan 2021 23:36

I'm not sure if this is fewer bytes or would make it run faster but…

Ans+16((Ans=0)-(Ans=17->X

Could be...

If max(Ans={0,17
17not(Ans→X

Re: 154 Byte Avalanche Game for TI-83/84+

J_Walker87 27 Jan 2021 00:20

I tried replacing my code with that, but it makes you go back to the center every time you move.

Re: 154 Byte Avalanche Game for TI-83/84+

J_Walker87 27 Jan 2021 00:23

Also, just to be clear, the code "Ans+16((Ans=0)-(Ans=17->X" serves to give the game screen-wrapping capability. It makes it so that if the player goes off the screen, they end up on the other side (much like if the game was played on a torus instead of a 2d surface).

Re: 154 Byte Avalanche Game for TI-83/84+

CalcNerd 27 Jan 2021 12:50

Sorry, I forgot one crucial part. The code should be like this…

Let me know if this solves the problem!

Ans+16((Ans=0)-(Ans=17->X

Could be...

If max(Ans={0,17
1+15not(Ans→X

Re: 154 Byte Avalanche Game for TI-83/84+

J_Walker87 27 Jan 2021 16:21

Thanks, that piece of code works great. One problem though, it adds two bytes of memory to the program because I have to then add a "→X" to the line before it. Thanks anyway though! Also, I noticed you referenced your Youtube channel in another post, so I subscribed to you.

Re: 154 Byte Avalanche Game for TI-83/84+

CalcNerd 27 Jan 2021 17:06

Thanks! I'm glad it worked! Have fun playing!

Re: 154 Byte Avalanche Game for TI-83/84+

Mr Bob Jr IV 27 Jan 2021 19:58

I found a great shave! You can change

L1(4->L1(5
L1(3->L1(4
L1(2->L1(3
L1(1->L1(2
randInt(1,16->L1(1

to

augment({randInt(1,16)},L1->L1
5->dim(L1

The augment command attaches the two lists together, so that L1 now has the random number on the front. Then change the dimension to 5 to remove the extra 6th element of the list. This also allows you to make another optimization at the beginning of the program. Since the 5->dim(L1 is used in the new block of code, you can remove it from the top! Augment needs you to define L1, though, so it goes from

DelVar L1
5->dim(L1

to

{0->L1

The final optimization I have is to change the (Ans=0) towards the bottom into not(Ans). It is not much, but every byte counts!

Re: 154 Byte Avalanche Game for TI-83/84+

J_Walker87 27 Jan 2021 20:06

Wow, thanks. Those changes brought the size down from 154 bytes to 122! I also had to make a minor change to the line "Output(8,Ans,0". It is now "Output(8,L1(1),0" in order to work with the changes you added.

Re: 154 Byte Avalanche Game for TI-83/84+

J_Walker87 27 Jan 2021 20:07

Also, the change caused the speed of the game to drop on my calculator, though not by too much. It doesn't really matter to me since the game is supposed to be optimized to take up as little space as possible, but it is worth noting.