2 Player Battle Game

Forum Attachments

Summary:

This is a 2 player battle game that I made and posted on my YouTube channel (CalcNerd). I hope you enjoy it! To move the Pi you use the arrow keys and the graph button to place a mine (randomly) on the screen. To move the i you use the X,t, theta,n button, the math button, the apps button, and the prgm button. To place a mine for the i, use the alpha button. You can lose by hitting either "mine".

2 Player Battle Game

CalcNerd 10 Apr 2020 14:01

This is a 2 player battle game that I made and posted on my YouTube channel (CalcNerd). I hope you enjoy it! To move the Pi you use the arrow keys and the [graph] button to place a mine (randomly) on the screen. To move the i you use the [X,t, theta,n] button, the [math] button, the [apps] button, and the [prgm] button. To place a mine for the i, use the [alpha] button. You can lose by hitting either "mine".

I am fairly new to Ti-Basic so I am very open to suggestions that all you Pros have :)! Here is the program…

:ClrDraw
:ClrHome
:16->X
:8->Y
:1->Z
:1->R
:1->G
:1->H
:1->A
:8->B
:0->K
:While 1 
:Lbl Theta      (I don't know how to get a theta)
:GetKey->K 
:ClrHome
:Output(R,Z,"* 
:Output(G,H,"* 
:Output(Y,X,"i        (the I from [2nd] [.])  
:Output(B,A,"PI      (I don't know how to get a Pi)  
:If K=32 
:Y-1->Y 
:If K=41
:X-1->X
:If K=43
:X+1->X
:If K=42
:Y+1->Y
:If K=24
:A-1->A 
:If K=25
:B-1->B 
:If K=26
:A+1->A 
:If K=34
:B+1->B
:If A=17
:1->A 
:If A=0
:16->A 
:If B=0
:8->B 
:If B=9
:1->B 
:If X=17
:1->X 
:If X=0
:16->X 
:If Y=9
:1->Y 
:If Y=0
:8->Y
:If A=H and B=G
:Goto 3
:If A=Z and B=R    
:Goto 4
:If X=H and Y=G
:Goto 5
:If X=Z and Y=R
:Goto 6
:If K=31
:Goto 1
:If K=15
:Goto 2
:End
:Lbl 1
:randInt(1,16)->Z
:randInt(1,8)->R
:Output(R,Z,"*"
:Goto Theta
:Lbl 2
:randInt(1,8)->G
:randInt(1,16)->H
:Output(G,H,"*"
:Goto Theta
:Lbl 3
:Lbl 4
:ClrHome
:Output(4,5,"i Wins!"
:Stop
:End
:Lbl 5
:Lbl 6
:ClrHome
:Output(4,5,"Pi Wins!"
:Stop 
:End

Re: 2 Player Battle Game

Z_dude 10 Apr 2020 15:53

Looks like a cool game! I watched the video on YouTube and read over your code, and I have a few suggestions:

Firstly, I would recommend reading through the page on Piecewise expressions. A lot of your code could be super improved by using them, and it would also make the code run faster, which is important for a game like this.

+ show block

:If K=41
:X-1→X
:If K=43
:X+1→X
Could be
:X+(K=41)-(K=43)→X
If you want to go really low on the byte count, you could try
:X+sum(ΔList(K={43,41→X
This can be extended to Y, A, and B.

Secondly, the code for looping around the screen is also repetitive and slow.

+ show block

:If X=17
:1->X 
:If X=0
:16->X
Could be
:If max(X={0,17
:17not(X→X
And this could be extended to the other positional variables, too

Thirdly, your code for placing the mines is really slow, because you are running Lbl and Goto commands, and Goto commands read through the entire program to find the correct Lbl command. In this case, you can remove the need for a Goto entirely.

+ show block

:If K=31
:Goto 1
...
:Lbl 1
:randInt(1,16)->Z
:randInt(1,8)->R
:Output(R,Z,"*"
:Goto Theta
can be replaced by
:If K=31:Then
:Output(R,Z,"       //That's 1 space
:randInt(1,16)->Z
:randInt(1,8)->R
:Output(R,Z,"*   //The closing quote isn't needed.
:End
You can do the same for if the other player places a mine.

Fourthly, (and this is a smaller one), you don't need to redraw the mines every single game loop. Just draw them once before Lbl θ, and then the code for placing a new mine will clear out the old mine and draw a new mine.

Fifthly, (is that a word? I'm not sure) the code for testing if the game is over can be improved. Try this:

+ show block

:If A=H and B=G
:Goto 3
:If A=Z and B=R    
:Goto 4
:If X=H and Y=G
:Goto 5
:If X=Z and Y=R
:Goto 6
can be
:If A=H and B=G or A=Z and B=R
:Goto 3
:If X=H and Y=G or X=Z and Y=R
:Goto 5
This eliminates the need for labels 4 and 6, and also speeds up the code.

Sixth of all, you have a memory leak, since you are using Goto commands to exit out of a loop. However, I don't use Goto
commands very often, so I have forgotten how to fix that.

Seventh, don't use Stop. It can lead to bugs with certain programs, and I believe it can mess up a lot if used in a shell. Always use Return.

And eighth, you mentioned that you couldn't find certain symbols, like →,∏,θ, and i. For the first three, try using the "Char" box in the corner of the screen. As for i, the imaginary number, I typically just write it as a regular i.

Keep up the good work! I noticed that you have a lot of stuff on your YouTube channel!

Edit: The pi I wrote above doesn't seem to have rendered properly. But it's in the Char box, and it works when you put it in a code block.

Last edited on 10 Apr 2020 15:54 by Z_dude Show more

Re: 2 Player Battle Game

CalcNerd 11 Apr 2020 15:14

Thanks so much! I am looking forward to revising it and making it much better!

I am reading up on all the things that you said to read. They are VERY helpful. Thank you so much!!!

Last edited on 11 Apr 2020 15:37 by CalcNerd Show more

Re: 2 Player Battle Game

CalcNerd 11 Apr 2020 17:33

I worked on the program today and made the revisions that you said to. I made a few of my own also. The characters are put in new spots at the start(so you won't die right away with one move) I will put the new code below. I checked my RAM before and after playing the game several times. The article on the memory leak said that the leak would lead to a dozen or so bytes lost in RAM. Since I didn't see any I think that there is no more leak. I also found the box for the symbols! Thanks so much for your help! I REAALLLYYY appreciate it!

One thing that isn't working (Only one). It might be my mistake and not yours. I am not sure. The code below didn't seem to work. When either of the characters goes off-screen it will give me an ERR:DOMAIN. I may have typed it in wrong???

:If X=17
:1->X 
:If X=0
:16->X
Could be
:If max(X={0,17
:17not(X→X

This is the "revised edition" :)

:ClrDraw
:ClrHome
:8→X
:3→Y
:1→Z
:1→R
:1→G
:1→H
:8→A
:5→B
:0→K
:While 1
:ClrHome
:Output(R,Z,"*
:Output(G,H,"*
:Lbl θ
:Output(Y,X,"i
:Output(B,A,"∏
:getKey→K
:Y+(K=42)-(K+32)→Y
:X+(K=43)-(K=41)→X
:A+(K=26)-(K=24)→A
:B+(K=34)-(K=25)→B

// this is the part that didn't work
:If max(X={0,17
:17not(X→X
:If max(Y={0,9
:9not(Y→Y
:If max(A={0,17
:17not(A→A
:If max(B={0,9
//end of part
:9not(B→B
:If A=H and B=G or A=Z and B=R
:Goto 1
:If X=H and Y=G or X=Z and Y=R
:Goto 2
:If K=31:Then
:Output(R,Z,"     //With 1 space
:randInt(1,16)->Z
:randInt(1,8)->R
:Output(R,Z,"*  
:End
:If K=15:Then
:Output(G,H,"       //with 1 space
:randInt(1,16)->H
:randInt(1,8)->G
:Output(G,H,"*  
:End
:End     // I don't know if this end is needed
:Lbl 1 
:ClrHome
:Output(4,5,"I WINS!
:Return
:End
:Lbl 2
:ClrHome
:Output(4,5,"∏ WINS!
:Return 
:End

Also, Would you like a shoutout on my youtube channel for helping me with this??

Last edited on 11 Apr 2020 21:53 by CalcNerd Show more

Re: 2 Player Battle Game

(account deleted) 11 Apr 2020 18:37

That End is needed before Lbl 1. Without it, the While loop would break. You don't need those Ends at the end of Lbl 1 and Lbl 2. :)

You only need End statements when you are closing For(, Repeat, and While loops.

Also, if you want better Pi symbols for reference…

𝜋 𝛑 𝝅 𝞹 ℼ

Don't paste those directly in TI-Connect CE, it won't work

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Last edited on 11 Apr 2020 18:41 by (account deleted) Show more

Re: 2 Player Battle Game

CalcNerd 11 Apr 2020 21:51

Ok, thank you for the clarification! Also, I don't have TI-Connect CE, so I have to put in everything in manually. Thanks for the help!

Re: 2 Player Battle Game

(account deleted) 12 Apr 2020 15:23

Man it would be nice if Wikidot had some things on here like Discord that would allow people to mention and contact each other quicker

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Re: 2 Player Battle Game

Z_dude 13 Apr 2020 12:58

Oh, I'm sorry. I wasn't paying enough attention to what I was writing. The code that wasn't working should be this:

:If max(X={0,17
:1+15not(X→X
and
:If max(Y={0,9
:1+7not(Y→Y

This is the way it works:
:If max(X={0,17
This compares the real number X to a list, {0,17}. When you compare a real number and a list using =,<,>, etc. a new list with the same dimensions as the list given is created, and each value is a 1 or a 0, depending on if the real number is equal to it. So if X is 17, X={0,17 will give the answer {0,1}. The max( command looks for the biggest value in that list, so if X is equal to 0 or 17, a value in the output list will be 1, so the max( command will return 1, which starts the If statement. If X is not equal to either value, then the max( command will read the largest value, 0, and therefore not trigger the If statement.

:1+15not(X→X
In this part, we look at X. If X is equal to 0, not(X will output 1, which is multiplied by 15, and then is added to 1, setting X to 16. If X is equal to 17, the not(X will produce 0, and 0 x 15 is 0, which is added to 1, setting X to 1. In this way, if the player is at X=0, 16 becomes the new X. If the player is at X=17, 1 becomes the new X.

Edit: I'm not sure why this is indenting oddly, and I don't know how to fix it.

Last edited on 13 Apr 2020 15:13 by Z_dude Show more

Re: 2 Player Battle Game

CalcNerd 13 Apr 2020 15:12

That is ok. Thank you for all of your help! I will shout you out on the video where I show this off! Thanks so much!

Re: 2 Player Battle Game

Z_dude 13 Apr 2020 15:14

A shoutout isn't necessary. I'm glad to have helped you with your project. Thank you for the offer, though!

Re: 2 Player Battle Game

CalcNerd 15 Apr 2020 21:10

Ok. Sorry. I missed the last comment. Apparently I am blind. I have a shoutout in the video for you. I could take it down if you don't want it in the video. Sorry for the trouble. Thanks soooooooooooooo much for all of the help. It really means A TON to me!!

Re: 2 Player Battle Game

TheWordSmither 22 Apr 2020 16:35

Here's my attempt at reducing. Cut down by ~100 bytes, with no overflow.

:16.8 -> X
:1.1->Z
:Z->H
:1.6->A
:0->Theta
:Repeat Theta
:Lbl Theta
:ClrHome
:Output(10fPart(Z),int(Z),"*
:Output(10fPart(H),int(H),"*
:Output(10fPart(X),int(X),"i
:Output(10fPart(A),int(A),"pi
:getKey->K
:X+(K=43)-(K=41)+.1((K=42)-(K=32->X
:A+(K=26)-(K=24)+.1((K=34)-(K=25->A
:fPart(A
:A+16((A<1)-(A>17))-.8((Ans>.8)-(not(Ans->A
:fPart(X
:X+16((X<1)-(X>17))-.8((Ans>.8)-(not(Ans->X
:max(A={H,Z})+2max(X={H,Z})->Theta
:If K=15
:randInt(1,16)+.1randInt(1,8)->Z
:If K=31
:randInt(1,16)+.1randInt(1,8)->H
:End
:ClrHome
:If Theta=1
:Output(4,5,"i Wins!
:If Theta=2
:Output(4,5,"pi Wins!

Hope this helps! If you have any questions don't hesitate to ask

Last edited on 22 Apr 2020 16:37 by TheWordSmither Show more

Re: 2 Player Battle Game

User748283 01 Aug 2020 23:15

Do you think you could make on with a Ai if not that's ok

Re: 2 Player Battle Game

CalcNerd 01 Aug 2020 23:42

Sure! I will post it here when I am done.