Analog(ue) Clock Display

Forum Attachments

Summary:

If anyone cares, this is a reference to thread #467224.

Analog(ue) Clock Display

(account deleted) 29 Mar 2020 00:47

I've been poking around the wiki a bit to find good analog clocks, and I found one I like. I saw and noticed some optimizations that could be made. The original program was 747 bytes, and now it is 658 bytes. Saved 89 bytes, increased performance in the digital clock and analog clock.

Show Original

:Lbl M
:ClrHome
:Menu(“CLOCK”,“ANALOGUE”,3,“DIGITAL”,2,“SET”,1,“ABOUT”,0,“QUIT”,Q
:Lbl 0
:Output(1,1,“CLOCK INTERFACE
:Output(2,1,“WOLFGANG47
:Output(8,12,“V.2.0
:Repeat getKey
:End
:Goto M
:Lbl 1
:DelVar ADisp “”,”
:Output(1,2,“12-HOUR
:Output(2,2,“24-HOUR
:Repeat K
:getKey→K
:End
:If max(K={25,34
:Then
:Output(A+1,1,“         //1 space
:not(A→A
:End
:End
:12
:AnsA+Ans→A
:setTmFmt(Ans
:Repeat Ans<A and 0=fPart(Ans
:Input “HOUR ”,B           //1 Space after "HOUR"
:End
:Repeat Ans≤60 and 0=fPart(Ans
:Input “MINUTE ”,C       //1 Space after "Minute"
:End
:setTime(B,C
:Pause getTmStr(0
:Goto M
:Lbl 2
:Repeat getKey
:getTmStr(24
:Output(1,1,Ans
:Output(1,6,“:
:getTime
:Ans(3→A
:Ans(Ans>9
:Output(1,7,Ans
:If Ans≤9
:Output(1,8,A
:End
:Goto M
:Lbl 3
:AxesOff
:GridOff
:FnOff
:PlotsOff
:ZStandard
:ZInteger
:Degree
:SetUpEditor
:ClrList L1
:3 -> dim(L1
:L1→L2
:Ans→L3
:Ans-1→L1
:Circle(0,0,30,{i
:For(A,1,12)
:90-30A→B
:44+round(24cos(Ans),0→C
:28-round(24sin(B),0→D
:Text(D,C,A
:If A≤9
:Text(D,C,0,A
:End
:Repeat getkey
:getTime→L4
:Ans(1
:L4(2)/12+5Ans-60(Ans>12→L4(1
:For(A,3,1,-1
:If not(L1(A)=L4(A
:Then
:Line(0,0,L2(A),L3(A),0
:L4(A→L1(A
:11A-2A^2+4→B
:90-6L1(A→C
:Bcos(Ans→L2(A
:Bsin(C→L3(A
:End
:End
:Pt-On(0,0,2
:Line(0,0,L2(3),L3(3
:Line(0,0,L2(2),L3(2
:Line(0,0,L2(1),L3(1
:End
:Goto M
:Lbl Q
:ClrList L1,L2,L3,L4
:DelVar ADelVar BDelVar CDelVar DDelVar KZStandard
:AxesOn
:ClrHome

Show New

:
Lbl M
ClrHome
Menu("CLOCK","ANALOG",3,"DIGITAL",2,"SET",1,"ABOUT",0,"QUIT",Q
Lbl 0
Disp "CLOCK INTERFACE","WOLFGANG47
Output(8,12,"V.2.1
Repeat getKey:End:Goto M
Lbl 1
DelVar ADisp " 12-HOUR"," 24-HOUR
Repeat max(Ans={25,34,45
getKey
End:Ans→K
If K≠45
setTmFmt(12+12(K=34
Repeat Ans<A and 0=fPart(Ans
Input "HOUR ",B
End
Repeat Ans≤60 and 0=fPart(Ans
Input "MINUTE ",C
End
setTime(B,C,0
Pause getTmStr(0
Goto M
Lbl 2
Output(1,6,":
Repeat getKey
Output(1,1,getTmStr(24
getTime
Ans(3→A
Ans(Ans>9
Output(1,7,Ans
If Ans≤9
Output(1,8,A
End
Goto M
Lbl 3
AxesOff
GridOff
FnOff 
PlotsOff 
ZStandard
ZInteger
Degree
SetUpEditor 
ClrList L₁
3→dim(L₁
L₁→L₂
Ans→L₃
Ans-1→L₁
Circle(0,0,30,{i
For(A,1,12)
90-30A→B
44+round(24cos(Ans),0→C
28-round(24sin(B),0→D
Text(D,C,A
If A≤9
Text(D,C,0,A
End
Repeat getKey
getTime→L₄
Ans(1
L₄(2)/12+5Ans-60(Ans>12→L₄(1
For(A,3,1,­1
If L₁(A)≠L₄(A
Then
Line(0,0,L₂(A),L₃(A),0
L₄(A→L₁(A
11A-2A^2+4→B
90-6L₁(A→C
Bcos(Ans→L₂(A
Bsin(C→L₃(A
End:End
Pt-On(0,0,2
For(I,1,3
Line(0,0,L₂(I),L₃(I
End:End
Goto M
Lbl Q
ClrList L₁,L₂,L₃,L₄
DelVar ADelVar BDelVar CDelVar KZStandard
AxesOn 
ClrHome

Changes made:

• Removed extra End command on line 23, caused a SYNTAX error.
• Changed the space on line 20 to a '>', to show what the user selected. Nothing was there before, so the space character didn't show anything that the user selected. It doesn't take extra memory.
• Moved the second colon on line 40 to under Lbl 2 in the digital clock to improve speed.
• Changed lines 87-89 and put them in a For( loop.

Note that the original program will need proper editing to be sent via TI-Connect CE.

I just decided to do this, I like optimizing random programs. And wow, this (account deleted) guy has spammed the living crap out of that thread lol

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Last edited on 30 Mar 2020 15:52 by (account deleted) Show more

Re: Analog(ue) Clock Display

bsch2734 29 Mar 2020 04:03

Haha, I remember this thread. If I remember correctly, one thing I didn't like about that clock was that the minute hand only moved every minute. In the one I wrote, the minute hand has a few intermediate positions each minute. Although mine flashes every seconds, and I don't think I ever got around to fixing that.

Re: Analog(ue) Clock Display

(account deleted) 30 Mar 2020 01:38

I wish I could make the analog clock faster, but I don't think I can optimize it further. I scanned the thread, and it seems like this user Thel 'Vadam has posted too much in that poor thread…

Too messy to navigate xD

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.