Factors of a whole number

Forum Attachments

Summary:

Trying to see if it is at all possible to make this smaller or know of a better way of going about it

Factors of a whole number

wifijoe 25 Feb 2019 20:20

Hello! It's… Been quite a while, though that's my fault. I've been working on this program recently, trying to make it smaller and smaller, and now I think it's the smallest it can get, unless there's a better way of going about it. It takes the input, A and uses a for( loop to go from 1 to A with the variable B. It uses a list and finds all of the factors that go into A. Willing to see anything on it! And no, I'm not very good with lists

:DelVar L₁1→C
:Input A
:For(B,1,A
:A/B→L₁(C:C+not(fPart(Ans→C
:End:L₁

Re: Factors of a whole number

kg583 25 Feb 2019 20:44

I would shy away from using DelVar with lists as it tends to mess with the SetUpEditor (even if it does save a byte).
Overall though the algorithm is tiny (though obviously not very efficient) so good job in that regard. I can't see any obvious major optimizations.

---

The solution to a complex problem is often a simple answer.

Re: Factors of a whole number

wifijoe 25 Feb 2019 22:52

okay, noted with the DelVar, and how could it be more efficient? I'm still somewhat new to a lot of these commands.

Re: Factors of a whole number

kg583 26 Feb 2019 02:02

Well, you've made it small but at the sacrifice of a rather slow factorization algorithm. You could speed it up by checking divisors only up to the square root of A rather than all the way to A:

:Input A
:{1,A→L₁
:For(B,2,√(A
:A/B
:If not(fPart(Ans:Then
:Ans→L₁(1+dim(L₁
:If Ans≠B:
:B→L₁(1+dim(L₁
:End:End

You could even add a bit of speed by only checking odd divisors if the input is odd:

:Input A
:{1,A→L₁
:For(B,2+remainder(A,2),√(A),1+remainder(A,2
:A/B
:If not(fPart(Ans:Then
:Ans→L₁(1+dim(L₁
:If Ans≠B:
:B→L₁(1+dim(L₁
:End:End

These do require the list to be sorted afterward, though (either with SortA( for ascending or SortD( for descending).

---

The solution to a complex problem is often a simple answer.

Re: Factors of a whole number

wifijoe 26 Feb 2019 04:08

…. Wow I have a lot to learn. That is so much faster and I don't really understand how it works… time to break it down! Seriously though, thanks for the examples, I have a lot to look at now in my off periods!

Edit: nevermind that was really easy to understand once I broke it down…. why didn't I ever think of that? again, thanks!

Last edited on 26 Feb 2019 04:14 by wifijoe Show more

Re: Factors of a whole number

(account deleted) 26 Feb 2019 15:55

Here is a factoring program I made:

Input A
For(B,1,A
If B>√(A
Stop
A/B
If Ans=int(Ans
Disp {B,Ans
End

This program is relatively small, it's 35 bytes not including the name.
This code will display factors as a list depending on the input. So, if the input were 30, you would get:

?30     //Input
         {1 30
         {2 15
         {3 10
         {5 6
         Done

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Last edited on 26 Feb 2019 15:56 by (account deleted) Show more