Optimize Me

Re: Optimize Me

Sun, 06 Jul 2014 11:45:28 +0000

:ClrHome
:Output(1,1,"MAKE YOUR WAY TOTHE EXIT WITHOUTGETTING CAUGHT..
:Pause
:DelVar Z3→C
:While C
:ClrHome
:3→A:1→B
:Repeat not(sum((A=L₁)(B=Ans
:randInt(1,6,4→L₁
:randInt(3,15,4→L₂
:End
:"-—-
:Output(7,1,Ans+Ans+"PTS=
:Output(8,5,Z
:Output(3,16,">
:Repeat A=3 and B=16 or sum((A=L₁)(B=L₂
:Output(8,17-C,"+++
:Repeat Ans
:getKey→W
:End
:Output(A,B,"
:min(6,max(1,A+sum(△list(Ans={25,34→A
:min(16,max(1,B+sum(△list(W={24,26→B
:Output(A,Ans,"+
:For(θ,1,4
:int(5rand→JFor(θ,1,4
:Output(L₁(θ),L₂(θ),"
:min(6,max(1,Ans+sum(△list(J={0,2→L₁(θ
:min(15,max(1,0+sum(△list(J={3,1→L₂(θ
:Output(L₁(θ),Ans,"*
:End
:End
:B=16→D
:C-not(Ans→C
:Z+D→Z
:End
:ClrHome
:Output(4,4,"GAME OVER
:Output(8,6,Z
:Output(8,8,"PTS
:Pause

I just mean

For(θ,1,4
:int(5rand→J
:L₂(θ→O
:L₁(θ
:Output(Ans,O,"
:min(6,max(1,Ans+sum(△list(J={0,2→L₁(θ
:min(15,max(1,0+sum(△list(J={3,1→L₂(θ
:Output(L₁(θ),Ans,"*
:End

Can be

For(θ,1,4
:int(5rand→J
:Output(L₁(θ),L₂(θ),"
:min(6,max(1,Ans+sum(△list(J={0,2→L₁(θ
:min(15,max(1,0+sum(△list(J={3,1→L₂(θ
:Output(L₁(θ),Ans,"*
:End

Not?

Re: Optimize Me

Wed, 21 Oct 2009 17:21:15 +0000

Of course. What did you have in mind?

Re: Optimize Me

Wed, 21 Oct 2009 16:37:17 +0000

Am I allowed to reccomend something to be optimized.

Re: Optimize Me

Sat, 21 Jun 2008 10:37:55 +0000

None of us started out being good at optimization; the only way you are going to get better at it is lots of practice.

Re: Optimize Me

Thu, 19 Jun 2008 13:16:14 +0000

For now, I won't participate in optimizing contests and stuff. Optimizing is something I'm not good at, lol.

Re: Optimize Me

Thu, 19 Jun 2008 13:05:16 +0000

k. Cool.

Re: Optimize Me

Wed, 18 Jun 2008 01:12:11 +0000

No, I did not. I saw it in a tutorial, and also saw DarkerLine use it.

Re: Optimize Me

Tue, 17 Jun 2008 20:21:32 +0000

btw Burr, that thing with min and max is sweet. Did u discover that?

Re: Optimize Me

Tue, 17 Jun 2008 17:46:09 +0000

I played the game. it works great, just ask darkstone knight. :D

Re: Optimize Me

Tue, 17 Jun 2008 15:06:39 +0000

yes, but max( is faster

LOL

Re: Optimize Me

Tue, 17 Jun 2008 14:30:52 +0000

Does that really work for "sum(△list(Ans={25,34"?

Re: Optimize Me

Tue, 17 Jun 2008 14:25:09 +0000

and since this is size optimization, you can use △list(!

:min(6,max(1,A+sum(△list(Ans={25,34→A :min(16,max(1,B+sum(△list(W={24,26→B

Re: Optimize Me

Tue, 17 Jun 2008 13:39:59 +0000

You can use the min( and max( commands:

:min(8,max(1,A+(Ans=34)-(Ans=25→A :min(16,max(1,B+(W=26)-(W=24→B

Re: Optimize Me

Tue, 17 Jun 2008 13:34:17 +0000

I've made a program smaller than darkerline's, and it works.:D 428 bytes.

:ClrHome :Output(1,1,"MAKE YOUR WAY TOTHE EXIT WITHOUTGETTING CAUGHT.. :Pause :DelVar Z3→C :While C :ClrHome :3→A:1→B :Repeat not(sum((A=L₁)(B=Ans :randInt(1,6,4→L₁ :randInt(3,15,4→L₂ :End :"-------- :Output(7,1,Ans+Ans+"PTS= :Output(8,5,Z :Output(3,16,"> :Repeat A=3 and B=16 or sum((A=L₁)(B=L₂ :Output(8,17-C,"+++ :Repeat Ans :getKey→W :End :Output(A,B," :min(6,max(1,A+sum(△list(Ans={25,34→A :min(16,max(1,B+sum(△list(W={24,26→B :Output(A,Ans,"+ :For(θ,1,4 :int(5rand→J :L₂(θ→O :L₁(θ :Output(Ans,O," :min(6,max(1,Ans+sum(△list(J={0,2→L₁(θ :min(15,max(1,0+sum(△list(J={3,1→L₂(θ :Output(L₁(θ),Ans,"* :End :End :B=16→D :C-not(Ans→C :Z+D→Z :End :ClrHome :Output(4,4,"GAME OVER :Output(8,6,Z :Output(8,8,"PTS :Pause

Re: Optimize Me

Mon, 26 May 2008 21:44:10 +0000

Yeah, you're right. That's good thinking outside the box :D

Re: Optimize Me

Mon, 26 May 2008 21:08:09 +0000

He's right, it does do the same thing. Just differently. Well done basickevin!

Re: Optimize Me

Mon, 26 May 2008 19:50:23 +0000

on another note, when I ran darkerline's program on my ti-83 +, it gave an error: domain message at
:For(J,1,4
:Output(L1(J),L2(J),"*
:End

Re: Optimize Me

Mon, 26 May 2008 17:14:42 +0000

yes it does, because the output command wraps text to the next line, which in this case is nonexisting, they do the same thing. I just ran them both on my calculator.

Re: Optimize Me

Mon, 26 May 2008 04:36:41 +0000

That doesn't do the same thing, though.

Re: Optimize Me

Mon, 26 May 2008 00:46:18 +0000

Hey burr, when you are displaying the plus signs for hp, you can have a much simpler code than what you posted.
Output(8,17-C,"+++

Re: Optimize Me

Wed, 06 Feb 2008 01:01:30 +0000

They are.

On the 68k calcs, you can tell the way a command works in this respect by the name. If a command returns a value, it starts with a lowercase letter and uses parentheses. If a command doesn't return anything (and possibly modifies some variables), it starts with an uppercase letter and no parentheses.

Re: Optimize Me

Tue, 05 Feb 2008 23:40:31 +0000

Are they the same way on the 68k calculators?

Re: Optimize Me

Tue, 05 Feb 2008 23:27:34 +0000

Well, SortA and SortD are special since they use an in-place sorting algorithm to allow you to sort 999-element lists. If they were to return a value, as you suggest, rather than modify an existing list, you'd run out of memory in that case.

Re: Optimize Me

Tue, 05 Feb 2008 23:03:17 +0000

It looks like you did a good job :D It's too bad that TI-Basic doesn't allow chaining of commands, that would be really helpful in optimizing:

:randInt(18,95,4→L3 :SortA(L3 could be :SortA(randInt(18,95,4→L3

Re: Optimize Me

Tue, 05 Feb 2008 22:43:39 +0000

Here's my optimized version, which might be a little larger than it should be in places I was showing off.

:ClrHome :Disp "MAKE YOUR WAY TO","THE EXIT WITHOUT :Pause "GETTING CAUGHT.. :3→C :0→Z :While 1 :ClrHome :3→A :1→B :Repeat min(ΔList(Ans :randInt(18,95,4→L3 :SortA(L3 :End :int(Ans/6→L2 :1+L3-6Ans→L1 :Output(7,1,"----------------PTS= :Output(8,5,Z :Output(8,14,sub(" +++",C,3 :Output(3,16,"> :Repeat max(A=L1 and B=L2 or Ans :Output(A,B,"+ :For(J,1,4 :Output(L1(J),L2(J),"* :End :Repeat Ans :getKey→K :End :Output(A,B,"(space) :A+(K=34 and A<6)-(K=25 and A>1→A :B+(K=26 and B<16)-(K=24 and B>1→B :randInt(1,5,4→L3 :For(J,1,4 :Output(L1(J),L2(J),"(space) :End :L1+(Ans=1 and L1<6)-(Ans=2 and L1>1→L1 :L2+(L3=3 and L2<15)-(L3=4 and L2>1→L2 :A=3 and B=16 :End :If Ans :IS>(Z,0 :DS<(C,1 :End :ClrHome :Disp "GAME OVER","POINTS: :Z

Re: Optimize Me

Tue, 05 Feb 2008 04:35:41 +0000

Thanks for telling me about the closing parentheses on the second line. I didn't even notice that. I actually found this game on the Internet, and just posted it verbatim; I didn't make any changes whatsoever.

Re: Optimize Me

Tue, 05 Feb 2008 04:29:54 +0000

You can use Ans for repeated strings.

:Output(7,1,"---------------- can be :"---- :Output(7,1,Ans+Ans+Ans+Ans

Here you can store all of the characters in a string and use the sub( command.

:If C=3 :Output(8,14,"+++ :If C=2 :Output(8,15,"++ :If C=1 :Output(8,16,"+ can be :Output(8,17-C,sub("+++",1,C

Everybody should recognize the movement code, and the subsequent optimization.

:Repeat Ans :getKey→Y :End :Output(A,B," (one space) :B+(Y=26 and B<16)-(Y=24 and B>1→B :A+(Y=34 and A<6)-(Y=25 and A>1→A

Re: Optimize Me

Tue, 05 Feb 2008 04:03:36 +0000

That's scary large o.O
It doesn't even run, you have a simple extra parenthesis on the second line.

:ClrHome :Output(1,1,"MAKE YOUR WAY TOTHE EXIT WITHOUTGETTING CAUGHT.. :Pause :DelVar Z3→C :Lbl A :ClrHome :3→A :1→B :1+int(6rand→D :3+int(13rand→E :Repeat F≠D or G≠E :1+int(6rand→F :3+int(13rand→G :End :Repeat H≠D or I≠E and H≠F or I≠G :1+int(6rand→H :3+int(13rand→I :End :Repeat N≠D or O≠E and N≠F or O≠G and N≠H or O≠I :1+int(6rand→H :3+int(13rand→I :End :Output(7,1,"----------------PTS= // (use 16 minus signs) :Output(8,5,Z :If C=3 :Output(8,14,"+++ :If C=2 :Output(8,15,"++ :If C=1 :Output(8,16,"+ :Output(A,B,"+ :Output(3,16,"> :"* :Output(D,E,Ans :Output(F,G,Ans :Output(H,I,Ans :Output(N,O,Ans :Lbl 0 :getKey→Y :Repeat Y :getKey→Y :End :If Y=24 and B≠1 :Then :Output(A,B," :B-1→B :End :If Y=25 and A≠1 :Then :Output(A,B," :A-1→A :End :If Y=26 and B≠16 :Then :Output(A,B," :B+1→B :End :If Y=34 and A≠6 :Then :Output(A,B," :A+1→A :End :Lbl 1 :1+int(5rand→J :If Ans=1 and D>1 :Then :Output(D,E," :D-1→D :End :If J=2 and E<15 :Then :Output(D,E," :E+1→E :End :If J=3 and D<6 :Then :Output(D,E," :D+1→D :End :If J=4 and E>1 :Then :Output(D,E," :E-1→E :End :1+int(5rand→K :If Ans=1 and F>1 :Then :Output(F,G," :F-1→F :End :If K=2 and G<15 :Then :Output(F,G," :G+1→G :End :If K=3 and F<6 :Then :Output(F,G," :F+1→F :End :If K=4 and G>1 :Then :Output(F,G," :G-1→G :End :1+int(5rand→L :If L=1 and H :Then :Output(H,I," :H-1→H :End :If L=2 and I<15 :Then :Output(H,I," :I+1→I :End :If L=3 and H<6 :Then :Output(H,I," :H+1→H :End :If L=4 and I>1 :Then :Output(H,I," :I-1→I :End :1+int(5rand→M :If M=1 and N>1 :Then :Output(N,O," :N-1→N :End :If M=2 and O<15 :Then :Output(N,O," :O+1→O :End :If M=3 and N<6 :Then :Output(N,O," :N+1→N :End :If M=4 and O>1 :Then :Output(N,O," :O-1→O :End :Lbl 2 :Output(A,B,"+ :"* :Output(D,E,"Ans :Output(F,G,"Ans :Output(H,I,"Ans :Output(N,O,"Ans :If A=D and B=E or A=F and B=G or A=H and B=I or A=N and B=O :Goto 99 :If A≠3 or B≠16 :Goto 0 :Z+1→Z :Goto A :Lbl 99 :C-1→C :If C≥1 :Goto A :ClrHome :Output(4,4,"GAME OVER :Output(8,2,"PTS = :Output(8,7,Z

That's what I have so far, I'm posting so it's saved, then I'll continue later. The structure sucks, if I get it working in a program,I might rewrite it :P

Optimize Me

Mon, 04 Feb 2008 05:28:14 +0000

As requested by Socks, the goal of this contest is to optimize a program as much as possible. The optimizations can either be for speed or size (or both), with that decision left up to the person who posted the program. Once everybody feels that a program can't be optimized any further, somebody can post a new program. When posting a program, please remember to change all of the TI-Basic tokens that don't display correctly to Unicode or something recognizable (see characters for a list of characters).

I'll start us off with a very unoptimized program, and the goal is to optimize for size.

:ClrHome :Disp "MAKE YOUR WAY TO","THE EXIT WITHOUT","GETTING CAUGHT.." :Pause :3→C :0→Z :Lbl A :ClrHome :3→A :1→B :randInt(1,6)→D :randInt(3,15)→E :Lbl B :randInt(1,6)→F :randInt(3,15)→G :If F=D and G=E :Goto B :Lbl C :randInt(1,6)→H :randInt(3,15)→I :If H=D and I=E :Goto C :If H=F and I=G :Goto C :Lbl D :randInt(1,6)→N :randInt(3,15)→O :If N=D and O=E :Goto D :If N=F and O=G :Goto D :If N=H and O=I :Goto D :Output(7,1,"----------------") (use 16 minus signs) :Output(8,1,"PTS=") :Output(8,5,Z) :If C=3 :Output(8,14,"+++") :If C=2 :Output(8,15,"++") :If C=1 :Output(8,16,"+") :Output(A,B,"+") :Output(3,16,">") :Output(D,E,"*") :Output(F,G,"*") :Output(H,I,"*") :Output(N,O,"*") :Lbl 0 :getKey→Y :While Y=0 :getKey→Y :End :If Y=24 and B≠1 :Then :Output(A,B," ") (put 1 space between the mark) :B-1→B :End :If Y=25 and A≠1 :Then :Output(A,B," ") :A-1→A :End :If Y=26 and B≠16 :Then :Output(A,B," ") :B+1→B :End :If Y=34 and A≠6 :Then :Output(A,B," ") :A+1→A :End :Lbl 1 :randInt(1,5)→J :If J=1 and D>1 :Then :Output(D,E," ") :D-1→D :End :If J=2 and E<15 :Then :Output(D,E," ") :E+1→E :End :If J=3 and D<6 :Then :Output(D,E," ") :D+1→D :End :If J=4 and E>1 :Then :Output(D,E," ") :E-1→E :End :randInt(1,5)→K :If K=1 and F>1 :Then :Output(F,G," ") :F-1→F :End :If K=2 and G<15 :Then :Output(F,G," ") :G+1→G :End :If K=3 and F<6 :Then :Output(F,G," ") :F+1→F :End :If K=4 and G>1 :Then :Output(F,G," ") :G-1→G :End :randInt(1,5)→L :If L=1 and H>1 :Then :Output(H,I," ") :H-1→H :End :If L=2 and I<15 :Then :Output(H,I," ") :I+1→I :End :If L=3 and H<6 :Then :Output(H,I," ") :H+1→H :End :If L=4 and I>1 :Then :Output(H,I," ") :I-1→I :End :randInt(1,5)→M :If M=1 and N>1 :Then :Output(N,O," ") :N-1→N :End :If M=2 and O<15 :Then :Output(N,O," ") :O+1→O :End :If M=3 and N<6 :Then :Output(N,O," ") :N+1→N :End :If M=4 and O>1 :Then :Output(N,O," ") :O-1→O :End :Lbl 2 :Output(A,B,"+") :Output(D,E,"*") :Output(F,G,"*") :Output(H,I,"*") :Output(N,O,"*") :If A=D and B=E :Goto 99 :If A=F and B=G :Goto 99 :If A=H and B=I :Goto 99 :If A=N and B=O :Goto 99 :If A=3 and B=16 :Goto 98 :Goto 0 :Lbl 98 :Z+1→Z :Goto A :Lbl 99 :C-1→C :If C<1 :Goto 97 :Goto A :Lbl 97 :ClrHome :Output(4,4,"GAME OVER") :Output(8,2,"PTS =") :Output(8,7,Z) :Stop