BCBetaTetris

Name: BC's Beta Tetris Author: ibly31 Download: BC's Beta Tetris Compatibility: Parent page not set File Size: 2334 Bytes

Fun beta Tetris in a small package!

What the community thinks:

source code

Jacobz54 03 Jan 2019 01:12

hey can you post the source code on here so i can manually put this in my calculator?

Re: source code

Myles_Zadok 03 Jan 2019 01:52

I extracted the .8xp file and opened it with SourceCoder3. I cannot confirm that it works, and it is also over 200 lines, so typing it in by hand will take a while. Here is the code anyway:

"Square
{~4,0,~4,4,0,4->L1
"Straight
{~8,0,~4,0,4,0->L2
"Diag-UpLeft
{4,0,0,4,~4,4->L3
"Diag-UpRight
{0,4,~4,0,4,4->L4
"CenterUp
{~4,0,4,0,0,4->L5
0->Xmin:94->Xmax
0->Ymin:62->Ymax
PlotsOff 
FnOff 
AxesOff
ClrDraw
For(I,0,62
    Pt-On(36,I,2
    Pt-On(84,I,2
End
Line(35,47,0,47
Line(35,6,0,6
Text(0,3,"BC's Beta
Text(7,7,"Tetris
Text(31,1,"Next Piece
0->L
Line(8,22,27,22
Line(27,22,27,14
Line(27,14,8,14
Line(8,22,8,14

Line(29,32,3,32
Line(3,43,29,43
Line(29,32,29,43
Line(29,43,29,32
Line(3,32,3,43
Line(35,24,0,24
Text(49,10,"Lines
randInt(1,5->B
B->Y
0->W
0->I
Lbl 1
If I=52:Goto EN
Text(57,1,"Score:",W
W+10->W
1->P
B->Y
randInt(1,5->B
17->S
35->T
Text(41,10,L
Text(~1,21,5,"    
If B=1:L1->L6
If B=2:L2->L6
If B=3:L3->L6
If B=4:L4->L6
If B=5:L5->L6
Pt-On(S,T,2
Pt-On(S+L6(1),T+L6(2),2
Pt-On(S+L6(3),T+L6(4),2
Pt-On(S+L6(5),T+L6(6),2
If Y=1:Then
    L1->L6
    80->Q
    44->R
End
If Y=2:Then
    L2->L6
    76->Q
    48->R
End
If Y=3:Then
    L3->L6
    76->Q
    44->R
End
If Y=4:Then
    L4->L6
    44->R
    76->Q
End
If Y=5:Then
    L5->L6
    44->R
    76->Q
End
randInt(13,19->X
4X->X
For(I,52,4,~4
    getKey->K
    Pt-Off(X,I+4,2
    Pt-Off(X+L6(1),I+L6(2)+4,2
    Pt-Off(X+L6(3),I+L6(4)+4,2
    Pt-Off(X+L6(5),I+L6(6)+4,2
    X+4(K=26)(X<Q)-4(K=24)(X>R)->X
    If K=25:Then
        P+1->P
        If P=5:1->P
        If Y=2:Then
            If P=3:1->P
            If P=1:Then
                {~8,0,~4,0,4,0->L6
                76->Q
                48->R
            End
            If P=2:Then
                {0,4,0,8,0,12->L6
                80->Q
                40->R
            End
        End
        If Y=3:Then
            If P=3:1->P
            If P=1:Then
                {4,0,0,4,~4,4->L6
                76->Q
                44->R
            End
            If P=2:Then
                {0,4,4,4,4,8->L6
                76->Q
                40->R
            End
        End
        If Y=4:Then
            If P=3:1->P
            If P=1:Then
                {0,4,~4,0,4,4->L6
                76->Q
                44->R
            End
            If P=2:Then
                {0,4,~4,4,~4,8->L6
                80->Q
                44->R
            End
        End
        If Y=5:Then
            If P=1:Then
                {~4,0,4,0,0,4->L6
                44->R
                76->Q
            End
            If P=3:Then
                {0,4,4,4,~4,4->L6
                76->Q
                44->R
            End
            If P=2:Then
                {0,4,0,8,4,4->L6
                40->R
                76->Q
            End
            If P=4:Then
                {0,4,0,8,~4,4->L6
                44->R
                80->Q
            End
        End
    End
    Pt-On(X,I,2
    Pt-On(X+L6(1),I+L6(2),2
    Pt-On(X+L6(3),I+L6(4),2
    Pt-On(X+L6(5),I+L6(6),2
    If pxl-Test(62-I+4,X) or pxl-Test(62-(L6(2)+I)+4,L6(1)+X) or pxl-Test(62-(L6(4)+I)+4,L6(3)+X) or pxl-Test(62-(L6(6)+I)+4,L6(5)+X):Then
        I-4->I
        Goto 2
    End
End
Lbl 2
Pt-On(X,I+4
Pt-On(X+L6(1),I+L6(2)+4
Pt-On(X+L6(3),I+L6(4)+4
Pt-On(X+L6(5),I+L6(6)+4
0->V
I+4->I
0->C
13->dim(L6
Fill(0,L6
For(J,36,84,4
    If pxl-Test(62-I,J:Then
        C+1->C
    End
    If pxl-Test(62-(I+4),J:Then
        J->L6((J-32)/4)
    End
End
If C!=13:Then
    Goto 1
End
For(J,40,80,4
    Pt-Off(J,I,2
    Pt-Off(J,I
End
L+1->L
W+10->W
0->L6(1):0->L6(13)
For(P,1,13
    If L6(P:Then
        Pt-Off(L6(P),I+4
        Pt-Off(L6(P),I+4,2
        Pt-On(L6(P),I,2
        Pt-On(L6(P),I
    End
End
For(theta,I+4,52,4
    For(Z,40,80,4
        If pxl-Test(62-theta,Z:Then
            Pt-Off(Z,theta,2
            Pt-Off(Z,theta
            Pt-On(Z,theta-4,2
            Pt-On(Z,theta-4
        End
    End
End
Goto 1

Lbl EN
For(I,35,43
    Line(23,I,80,I
End

For(theta,0,8
    Text(~1,20,25+6theta,sub("GAME OVER",theta+1,1
For(Z,0,50:End
End

For(I,16,34
    Line(23,I,80,I,0
End
Line(23,34,80,34
Line(23,34,23,16
Line(80,16,80,34
Line(23,16,80,16
Text(~1,30,25,"Score Was
StorePic 1
FnOff 
{0,1->L1
{0,W->L2
FnOff 
LinReg(ax+b) {Y1}
FnOff 
Equ>String({Y1},Str1
FnOff 
sub(Str1,1,length(Str1)-3->Str1
RecallPic 1
Text(~1,38,52-(length(Str1)*3),W
Repeat getKey:End
For(I,0,22
    Vertical I
End
Line(22,16,22,43,0
For(I,23,80
    Line(I,45,I,62
    Line(I,15,I,0
    Pt-Off(I,44
    Pt-Off(I,15
End
Vertical 81
Line(81,16,81,43,0
For(I,82,94
    Vertical I
End
Repeat getKey:End
For(I,22,82
    Vertical I
End
prgmCH2

Re: source code

PhillMiaz 23 Apr 2019 23:00

This line gets an invalid error for this line
LinReg(ax+b) {Y1}

Re: source code

Trenly 23 Apr 2019 23:24

That is SourceCoder3 notation, not the notation for the calculator. You will need to remove the { and }, and be sure to use the Y₁ variable found in the Vars menu and not typing in Y1

Re: source code

Jacobz54 26 Feb 2019 18:51

does the indentation matter?

Re: source code

Deoxal 26 Feb 2019 22:55

Programs shouldn't have any indentation at all. I think he added those to make it easier for you to type it in on your calculator. If he didn't add those spaces then there is no way this code would work.

---

4920616D204261746D616E

Trenly 26 Feb 2019 23:23

The indentations help when programming code with a lot of For, While, Repeat, or If-Then blocks. When you enter the block, you add an indent, and when you put an end statement you remove an indent. It helps make sure there is the proper number of end statements, and is very useful when checking for memory leaks.

Just so everybody knows

Bio_Hazard1282_rPi3 27 Feb 2019 18:32

The ~s are negative signs.

---

𝔹𝕚𝕠_ℍ𝕒𝕫𝕒𝕣𝕕𝟙𝟚𝟠𝟚

It works...

Caleb Zierenberg 27 Feb 2019 20:00

So I spent half an hour typing it in, since I don't have a ti to usb cord either, and it works. Just a heads up for anyone else typing it in by hand, when it says "Theta" use the variable theta, don't spell it out. And like Boi_Hazard1282 said the "~" signs are negatives.

why does there say prgm ch2

m3m3b01 24 Jan 2020 18:30

why

Re: why does there say prgm ch2

Bio_Hazard1282_rPi3 25 Jan 2020 23:56

That's the main program name

---

𝔹𝕚𝕠_ℍ𝕒𝕫𝕒𝕣𝕕𝟙𝟚𝟠𝟚

Want to update this page?

• Upload new files to provide up-to-date versions of your program;
• or Edit the content of this page to provide up-to-date information about your program.

A moderator will only process these changes if you add the word update to the list of tags