Shades CE

You have not uploaded your program! Please edit the page to upload your program.

Author: Michael2_3B Download: SHADES84PCE.zipNo Download Available Version: 1.2 Compatibility: TI-84+ CE File Size: 2002 Bytes Genre: Arcade Graphics Platform Puzzle RPG Strategy Sports Casino Board Utility Misc Rating:
Shades is a simple, zen-like game for the TI-84 Plus CE. It is like a merge between Tetris and 2048. Combine tiles together in order to rack up the most points you possibly can! Just don't let the tiles stack to the top of screen! This is a port of the original iOS game created by UOVO. See the README for more info.

What the community thinks:

ERROR

Zixcoder 16 May 2017 05:06

So, it seems to be that whenever the blocks get to the top of the screen, the game crashes. This is quite a problem especially if you had a new highscore. Could you fix this? Thanks!

Re: ERROR

Battlesquid 16 May 2017 06:08

You can find the most up to date program here.

---

Re: ERROR

Michael2_3B 03 Sep 2017 05:09

(I realize this is an old post, my apologies. I am only just now seeing this)

I noticed this bug as well, but I haven't been able to pinpoint the cause. I'm sure I could look at the code again, however the bug does not occur often enough for me to take the time to do so.

In case if users want...

(account deleted) 22 Oct 2017 10:31

here is the source code:

StoreGDB 9
0→Xmin:264→Xmax
0→Ymin:164→Ymax
FnOff 
CoordOff:GridOff:AxesOff
SetUpEditor SHADE,SHD
UnArchive ⌊SHADE
If not(dim(⌊SHADE
{1,0→⌊SHADE
Lbl 1
ClrDraw
BackgroundOff
Disp 
DispGraph
For(A,164,0,­3
12(A>134)+(A<135)(22+int(A/45
Line(0,A,30,A,Ans
Line(234,A,264,A,Ans
End
TextColor(BLACK
Text(­1,20,70,"==SHADES==
TextColor(DARKGRAY
Text(­1,50,100,"START
TextColor(GRAY
Text(­1,80,87,"OPTIONS
Text(­1,110,105,"QUIT
50→A:TextColor(BLACK
Repeat sum(K={21,105
getKey→K
int(­.0172A²+2.6722A-51.556
Text(­1,A,124-Ans,"<
Text(­1,A,124+Ans,">
If sum(K={25,34
Then
Text(­1,A,124-Ans," "
Text(­1,A,124+Ans," "
max(50,min(110,A+30sum(List(K={25,34→A
End
End
If A=110
Then
ClrDraw
ClrHome
Return
End
If A=80
Then
ClrHome
ClrDraw
⌊SHADE(1→S
BackgroundOn Ans+9+(Ans≥3
Disp :DispGraph
Text(150,0,"Background:
Repeat max(K={105,45,21
getKey→K
Text(150,90,"< ",sub("BLUEREDMAGENTAGREENORANGEBROWNNAVYLTBLUEYELLOWWHITE",S,1)," >
If sum(K={24,26
Then
"                  "
Ans+Ans+Ans
Text(150,90,Ans+Ans
S-10(K=26)(S=10)+10(K=24)(S=1)+sum(List(K={24,26→S
BackgroundOn Ans+9+(Ans≥3
Disp :DispGraph
End
End
S→⌊SHADE(1
End
If A=80
Goto 1
Lbl T
ClrDraw
⌊SHADE(1→S
BackgroundOn Ans+9+(Ans≥3
BorderColor 1
Disp :DispGraph
{12,12,12,24,23,22,21,20
For(Z,0,7
Line(0,2Z,125,2Z,Ans(Z+1
End
Line(122,0,122,164,BLACK
Line(124,0,124,164,BLACK
DelVar [A]{11,4→dim([A]
For(Z,1,4
1→[A](11,Z
End
"           "
Ans+Ans+Ans+Ans+Ans+Ans
For(Z,0,150,14
Text(Z,126,Ans+" "
End
Text(150,126,Ans+" 
Line(263,0,263,164,WHITE
Line(261,0,261,164,WHITE
Line(259,0,259,164,WHITE
Line(126,164,264,164,WHITE
Text(­1,14,160,"SHADES
Text(29,135,"Michael2   3B ,
Line(196,124,201,124,BLACK
Text(29,230,"PT
Line(246,124,251,124,BLACK
Text(­1,60,160,"Score:
Text(­1,100,160,"High:
Text(­1,120,160,⌊SHADE(2
164→A
1→B
0→H
{0,0,0,0→⌊SHD
randInt(LTGRAY,DARKGRAY→C
Lbl R
Repeat K=22 or K=45 or max(seq([A](1,X),X,1,4
getKey→K
If [A](11-int(A/15),B
Then
C→[A](10-int(A/15),B
H+2→H
Text(­1,80,160,Ans
1+⌊SHD(B)→⌊SHD(B
If min(seq(C=[A](θ,X),X,1,4
Then
{15,0,60,15θ
Asm(prgmZSHADES
Disp :DispGraph
H+200→H
Text(­1,80,160,Ans
⌊SHD
Ans-(Ans≠0→⌊SHD
[A]
For(X,2,θ
rowSwap(Ans,X,1
End
Ans→[A]
For(Z,1,4
0→[A](1,Z
End
End
randInt(1,4→B
164→A
randInt(LTGRAY,DARKGRAY→C
End
If A=164
Then
17+15⌊SHD(B
Line(30B-29,Ans,30B,Ans,C
End
B→F
max(1,min(4,B+sum(List(K={24,26→B
If Ans≠F
Then
If not([A](min(11,θ+2),Ans
Then
17+15⌊SHD(F
Line(30F-29,Ans,30F,Ans,0
17+15⌊SHD(B
Line(30B-29,Ans,30B,Ans,C
For(Z,A+9,A-6,­3
Line(30B-29,Z,30B,Z,C
Line(30F-29,Z+6,30F,Z+6,0
End
A-6→A
Else
F→B
End
End
Line(30B-29,A,30B,A,C
Line(30B-29,A+15,30B,A+15,0
A-3→A
If K=34 and not([A](min(11,12-int(A/15)),B
Then
For(Z,A+15,A,­3
Line(30B-29,Z,30B,Z,0
End
2+15(1+⌊SHD(B→A
For(Z,A+15,A,­3
Line(30B-29,Z,30B,Z,C
End
Repeat [A](11-int(A/15),B
Line(30B-29,A,30B,A,C
Line(30B-29,A+15,30B,A+15,0
A-3→A
End
End
If K=45
Goto E
10-int(A/15→θ
If C=[A](Ans+1,B
Then
0→J
10-int(A/15→θ
While C=[A](Ans+1,B) and 25>[A](Ans+1,B
1+[A](Ans+1,B→[A](Ans+1,B
0→[A](θ,B
C+1→C
J+1→J
⌊SHD(B)-1→⌊SHD(B
For(Z,A+3,A-12,­3
Line(30B-29,Z,30B,Z,C-13(C=25
Line(30B-29,Z+15,30B,Z+15,0
End
H+4^J→H
Text(­1,80,160,Ans
A-15→A
θ+1→θ
End
End
Lbl E
End
If K=22
Then
ClrHome
Output(3,11,"PAUSED
Output(5,7,"[mode] resume
Output(6,7,"[stat] restart
Output(7,7,"[clear] quit
Repeat sum(Ans={22,33,45
getKey→K
End
ClrHome
End
If K=22
Goto R
If K=33
Goto T
ClrDraw
ClrHome
If K≠45
Output(5,9,sub("GAME OVER! HIGH SCORE!",11(H>⌊SHADE(2))+1,11
Output(6,9,"SCORE:
Output(6,15,H
rand(100
If H>⌊SHADE(2
H→⌊SHADE(2
DelVar [A]DelVar ⌊SHD
Archive ⌊SHADE
RecallGDB 9
DelVar GDB9
BackgroundOff

---

Hewwo, my name is Achak Claw. I was formerly BioHazard.

Re: In case if users want...

Michael2_3B 20 May 2018 04:12

This is great, however the file ZSHADES.8xp is not typable (it is an assembly subprogram), and is required to make the game work.

Lowercase

GreenGuy5294 27 Apr 2018 16:08

I'm sitting in class bored because I have nothing to do, and I'm manually typing the source code for this game into my class's TI 84 lol.
How do I type in the lowercase numbers?

Re: Lowercase

Trenly 27 Apr 2018 16:16

You need to use a hexcode to enable typing lowercase. In addition, note that the game code nor this hexcode will work on an 84, 84+, or 84+ SE. They will only work on the CE and CSE models.

The hexcode for lowercase is found on the 84+ CSE Hexcodes Page

Re: Lowercase

Michael2_3B 20 May 2018 04:08

Please note that the game will NOT work unless you download ZSHADES from the file as well onto the calculator. This is an assembly program that is NOT typable on the calculator, and it is necessary to graphically remove rows of tiles.