Maze

You have not uploaded your program! Please edit the page to upload your program.

Author:

Joseph Walker
Download: MAZE.8xpNo Download Available
Version: 2.1
Compatibility: TI-83/84/+/SE
File Size: 611 Bytes
Genre: Arcade Graphics Platform Puzzle RPG Strategy Sports Casino Board Utility Misc
Rating:
TI|BD

This is an updated version of the game that I made for CalcNerd to post on his youtube channel. It features larger mazes and new custom game menus.

IMPORTANT: Before playing the game for the first time, type [2nd][PRGM][left arrow key][ENTER][0][ENTER]. Make sure to press NEW MAZE on the game menu the first time you play.

To play, select an option from the menu. When the maze is ready, a pixel for you to move through the maze will appear in the top left corner. If you can't see the pixel, use the arrow keys to move it until you see it moving. To win the game, get to the bottom right corner of the maze. You can quit by pressing [CLEAR]. Don't worry if you get stuck, just quit to save the maze for later. You can select 'LOAD MAZE' on the menu screen to load in the previous maze. Have fun!

Here's the code in Source Coder 3 format if you want to type it in or are curious about how it works:

ClrDraw
0->Xmin
94->Xmax
0->Ymax
~62->Ymin
AxesOff
RecallPic 0
Lbl 1
For(Y,~17,~45,~1
    Line(23,Y,71,Y,0
End
Line(24,~46,72,~46
Line(72,~18,72,~46
Text(~1,18,24,"MAZE 2.1
Text(26,28,"LOAD MAZE
Text(32,28,"NEW MAZE
Text(38,28,"QUIT
~29->Y:0->K
Repeat K=21 or K=105
    Pt-On(25,Y,2
    Repeat K
        getKey->K
    End
    Pt-Off(25,Y,2
    6sum(DeltaList(K={34,25
    Y+(Y>~41 or Ans!=~6)(Y<~29 or Ans!=6)Ans->Y
End
If Y=~29
Goto 0
If Y=~41
Then
    ZStandard
    AxesOn
    ClrHome
    Return
End
ClrDraw
For(Y,0,~62,~2
    Horizontal Y
End
For(X,0,94,2
    Vertical X
End
Line(1,~1,1,~61,0
Line(1,~1,93,~1,0
For(X,3,93,2
    For(Y,3,61,2
        randInt(0,1
        Pxl-Off(Y-Ans,X-not(Ans
    End
End
Pxl-Off(61,94
StorePic 0
Lbl 0
ClrDraw
RecallPic 0
0->K:1->X:1->Y
Repeat K=45 or X=95
    Pxl-On(Y,X
    Repeat K
        getKey->K
    End
    Pxl-Off(Y,X
    sum(DeltaList(K={25,34
    Y+2Ansnot(pxl-Test(Y+Ans,X->Y
    sum(DeltaList(K={24,26
    X+2Ansnot(pxl-Test(Y,X+Ans->X
End
If X=95:Then
    Line(23,~8,23,~17,0
    For(X,0,7
        Text(~1,9,24+6X,sub("YOU WIN!",X+1,1
        Line(24+6X,~8,29+6X,~8,0
        For(Y,1,100
End:End:End
Goto 1

What the community thinks:

Add a New Comment
Unless otherwise stated, the content of this page is licensed under Creative Commons Attribution-Noncommercial 2.5 License.