Lunar Lander

You have not uploaded your program! Please edit the page to upload your program.

Author:

Joseph Walker
Download: LANDER.8xpNo Download Available
Version: 1.0
Compatibility: TI-83/84/+/SE
File Size: 732 Bytes
Genre: Arcade Graphics Platform Puzzle RPG Strategy Sports Casino Board Utility Misc
Rating:
TI|BD

IMPORTANT: Before playing the game for the first time or after a calculator RAM reset, press [2nd][PRGM][left arrow key][ENTER][9][ENTER]. Make sure to select 'NEW' on the game menu the first time you run the game.

You can load or generate new terrain using the main menu. When the game starts, you will see a white pixel representing your lander. To apply thrust, press the up arrow key. To change your craft's angle, use the left and right arrow keys. The angle of your lander is displayed in the top left corner. If your lander is upright, the angle will be 90. To land, slow down and make sure you are oriented at 90 degrees. Then touch down carefully.

Here's the code in Source Coder 3 format if you want to type the game into your calc or you're just curious about the code:
Degree
0->Xmin
94->Xmax
0->Ymax
~62->Ymin
2->Xres
AxesOff
Lbl 0
ClrDraw
RecallPic 9
For(Y,5,32
Line(30,~Y,66,~Y,0
End
Text(~1,6,31,"LANDER
Text(14,35,"LOAD
Text(20,35,"NEW
Text(26,35,"QUIT
0->K:~17->Y
Repeat max(K={105,21
Pt-On(32,Y,2
Repeat K
getKey->K
End
Pt-Off(32,Y,2
6sum(DeltaList(K={34,25
Y+Ans(Y!=~17 or Ans!=6)(Y!=~29 or Ans!=~6->Y
End
If Y=~29
Then
ZDecimal
AxesOn
ClrHome
Return
End
If Y=~17
Goto 1
ClrDraw
seq(5-10rand,X,1,3->L1
For(Y,0,~62,~1
Horizontal Y
End
For(X,0,94
Line(X,~62,X,L1(1)sin(3X)+L1(2)cos(6X)+L1(3)sin(12X)-50,0
End
DelVar L1StorePic 9
Lbl 1
ClrDraw
RecallPic 9
0->K:90->A
0->Y:47->X
0->H:0->V
Repeat K=45 or Y+V<0 or X+H<0 or X+H>94 or not(pxl-Test(1+int(Y),int(X
Text(~1,0,0,"
Text(0,0,A
Pxl-On(int(Y),int(X
Y+V->Y
X+H->X
Pxl-Off(int(Y),int(X
getKey->K
A+15sum(DeltaList(Ans={26,24->A
H+.5(K=25)cos(Ans->H
V-.1(K=25)sin(A)+.05->V
End
If K=45
Goto 0
If int(X+H)<0 or int(X+H)>94 or int(Y+V)<0 or int(X+H)<=17 and Y<=7
Then
"GOTLOST
Else
If A=90 and abs(H)<=1 and abs(V)<=1 and pxl-Test(int(Y),int(X)-1) and pxl-Test(int(Y),1+int(X)) and not(pxl-Test(int(Y)+1,int(X
Then
"LANDED!
Else
"CRASHED
End
End
For(X,1,11
Text(~1,20,6X+8,sub("YOU "+Ans,X,1
For(Y,1,100
End
End
For(Y,1,1000
End
Goto 0

What the community thinks:

Add a New Comment
Unless otherwise stated, the content of this page is licensed under Creative Commons Attribution-Noncommercial 2.5 License.